Android Gradle学习(七):Gradle构建生命周期

Gradle 进行构建,都要经过3个生命周期阶段:

  • 初始化阶段
  • 配置阶段
  • 执行阶段

Gradle 提供了很多生命周期监听方法,可以在各个阶段 Hook 指定的任务。

1. Project

Project 提供的生命周期回调方法有:

//在 Project 进行配置前调用
void beforeEvaluate(Closure closure)
//在 Project 配置结束后调用
void afterEvaluate(Closure closure)

beforeEvaluate 必须在父模块的 build.gradle 对子模块进行配置才能生效,因为在当前模块的 build.gradle 中配置,它自己本身都没配置好,所以不会监听到。

我们用个例子来验证下结果,工程结构如下图所示:

测试代码工程结构

settings.gradle 代码:

include ":app"

build.gradle 代码:

//对子模块进行配置
subprojects { sub ->
    sub.beforeEvaluate { proj ->
        println "子项目beforeEvaluate回调..."
    }
}

println "根项目配置开始---"

task rootTest {
    println "根项目里任务配置---"
    doLast {
        println "执行根项目任务..."
    }
}

println "根项目配置结束---"

app/build.gradle 代码:

println "APP子项目配置开始---"

afterEvaluate {
    println "APP子项目afterEvaluate回调..."
}

task appTest {
    println "APP子项目里任务配置---"
    doLast {
        println "执行子项目任务..."
    }
}

println "APP子项目配置结束---"

在根目录执行:gradle -q,结果如下:

根项目配置开始---
根项目里任务配置---
根项目配置结束---
子项目beforeEvaluate回调...
APP子项目配置开始---
APP子项目里任务配置---
APP子项目配置结束---
APP子项目afterEvaluate回调...

2. Gradle

Gradle 提供的生命周期回调方法很多,部分与 Project 里的功能雷同:

//在project进行配置前调用,child project必须在root project中设置才会生效,root project必须在settings.gradle中设置才会生效
void beforeProject(Closure closure)

//在project配置后调用
afterProject(Closure closure)

//构建开始前调用
void buildStarted(Closure closure)

//构建结束后调用
void buildFinished(Closure closure)

//所有project配置完成后调用
void projectsEvaluated(Closure closure)

//当settings.gradle中引入的所有project都被创建好后调用,只在该文件设置才会生效
void projectsLoaded(Closure closure)

//settings.gradle配置完后调用,只对settings.gradle设置生效
void settingsEvaluated(Closure closure)

我们修改 setting.gradle 的代码如下:

gradle.settingsEvaluated {
    println "settings:执行settingsEvaluated..."
}

gradle.projectsLoaded {
    println "settings:执行projectsLoaded..."
}

gradle.projectsEvaluated {
    println "settings: 执行projectsEvaluated..."
}

gradle.beforeProject { proj ->
    println "settings:执行${proj.name} beforeProject"
}

gradle.afterProject { proj ->
    println "settings:执行${proj.name} afterProject"
}

gradle.buildStarted {
    println "构建开始..."
}

gradle.buildFinished {
    println "构建结束..."
}

include ":app"

这个时候的执行结果如下:

settings:执行settingsEvaluated...
settings:执行projectsLoaded...
settings:执行test beforeProject
根项目配置开始---
根项目里任务配置---
根项目配置结束---
settings:执行test afterProject
settings:执行app beforeProject
子项目beforeEvaluate回调...
APP子项目配置开始---
APP子项目里任务配置---
APP子项目配置结束---
settings:执行app afterProject
APP子项目afterEvaluate回调...
settings: 执行projectsEvaluated...
构建结束...

可以看到 gradle.beforeProject 与 project.beforeEvaluate 是类似的,同样 afterProject 与 afterEvaluate 也是类似的。

除此之外,Gradle 还有一个通用的设置生命周期监听器的方法:addListener

上面的 BuildListener、ProjectEvaluationListener 等与前面的部分 API 功能是一致的,这里不再赘述了。

3. TaskExecutionGraph(Task执行图)

Gradle 在配置完成后,会对所有的 task 生成一个有向无环图,这里叫做 task 执行图,他们决定了 task 的执行顺序等。同样,Gradle 可以对 task 的执行生命周期进行监听。

//任务执行前掉用
void afterTask​(Closure closure)
//任务执行后调用
void beforeTask(Closure closure)
//任务准备好后调用
void whenReady(Closure closure)

通过 gradle.getTaskGraph() 方法来获取 task 执行图:

TaskExecutionGraph taskGraph = gradle.getTaskGraph()
taskGraph.whenReady {
    println "task whenReady"
}

taskGraph.beforeTask { Task task ->
    println "任务名称:${task.name} beforeTask"
}

taskGraph.afterTask { Task task ->
    println "任务名称:${task.name} afterTask"
}

4. 小结

生命周期回调的执行顺序:

gradle.settingsEvaluated->
gradle.projectsLoaded->
gradle.beforeProject->
project.beforeEvaluate->
gradle.afterProject->
project.afterEvaluate->
gradle.projectsEvaluated->
gradle.taskGraph.graphPopulated->
gradle.taskGraph.whenReady->
gradle.buildFinished
系列文章

Android Gradle学习(一):Gradle基础入门
Android Gradle学习(二):如何创建Task
Android Gradle学习(三):Task进阶学习
Android Gradle学习(四):Project详解
Android Gradle学习(五):Extension详解
Android Gradle学习(六):NamedDomainObjectContainer详解
Android Gradle学习(七):Gradle构建生命周期
Android Gradle学习(八):统计Task执行时长

推荐阅读更多精彩内容