脚本功能
- 在windows上多开微信
- 检测到有正在运行的微信将结束正在运行的进程
- 启动后将检测微信有没有打开，防止有人脚本直接退出有人会多次打开脚本
- 建议多开数量不要太大，否则会很卡，具体上限多少自行测试
- win7和win10上均可使用（2020-06-14）
话不多说，直接上内容；
@if "%DEBUG%" == "" @echo off
:: AUTHOR_BASE64: 5Yi25Lu26ICFUVE6IDQ4NjExMDI0
title 微信多开脚本 v1.1
::启动后需要稍等一会
::微信的路径可以在此设置，注意使用引号，并且引号是英文的；例如：
::set WX_PATh="D:\Program Files (x86)\Tencent\WeChat\WeChat.exe"
set WX_PATH=""
::如果没有设置，可以使用拖入快捷方式/主程序的形式打开微信
::拖入的优先级别高于此处设置的路径
::下面这行设置微信打开的个数，默认为2
set MULTI=2
set TMP_WX_PATH="%~1"
if not %TMP_WX_PATH% == "" set WX_PATH="%~1"
if %WX_PATH% == "" goto end
if not exist %WX_PATH% goto end
::检测微信是否正在运行
tasklist | find /i "WeChat.exe" >nul 2>nul && goto killWx || goto start
:killWx
echo.
echo 检测到微信正在运行
echo 需要先关闭微信才能多开
echo 按任意键关闭微信，否则直接关闭当前窗口
pause>nul
taskkill /f /im WeChat.exe
:start
for /l %%i in (1,1,%MULTI%) do start "" %WX_PATH%
echo.
echo 微信正在启动中，请稍等...
::检测运行情况
:check
ping 127.1 -n 2 >nul 2>nul
echo ...
tasklist | find /i "WechatBrowser.exe" >nul 2>nul && goto finish || goto check
:finish
echo.
echo 微信启动成功!
ping 127.1 -n 3 >nul 2>nul
exit /b 1
:end
echo.
echo.
echo 微信的路径不存在或者路径错误: %WX_PATH%
echo.
echo.
echo ##########################################################################
echo.
echo 使用方法
echo 1. 直接拖动快捷方式或者文件到此批处理上
echo 2. 微信路径: 修改本脚本中 WX_PATH 内容
echo 3. 多开个数: 修改本脚本中 MULTI 内容
echo 4. 优先使用拖动的方式
echo.
echo ##########################################################################
echo.
pause
新建txt文档，复制以上内容到文档中，保存并关闭文档，修改文档后缀名为.bat，有的电脑默认不展示后缀名，自行百度如何展示
