windows DOS批处理.bat

  • 批处理符号简介

回显屏蔽 @

表示不显示@后面的命令
@用法举例:通过运行批处理文件对比pause和@pause命令即可明了@的效果。

重定向1 >与>>

将输出信息重定向到指定的设备或文件。系统默认输出到显示器。
\>清除文件中原有的内容后再写入
\>\>追加内容到文件末尾,而不会清除原有的内容主要将本来显示在屏幕上的内容输出到指定文件中指定文件如果不存在,则自动生成该文件
====================================================
echo hello world>c:/test.txt   生成c:/test.txt文件,内容为hello world这个格式在批处理文件里用得很多,可以生成.reg .bat .vbs 等临时文件
type c:/test.txt >prn          屏幕上不显示文件内容,转向输出到打印机
echo hello world>con           在屏幕上显示hello world,实际上所有输出都是默认 >con 的
copy c:/test.txt f: >nul       拷贝文件,并且不显示"文件复制成功"的提示信息,但如果f盘不存在,还是会显示出错信息
copy c:/test.txt f: >nul 2>nul 不显示"文件复制成功"的提示信息,并且f盘不存在的话,也不显示错误提示信息
echo ^^W ^> ^W>c:/test.txt     生成的文件内容为 ^W > W^ 和 > 是控制命令,要把它们输出到文件,必须在前面加个 ^符号
================================================

重定向2 <

将输入信息来源重定向为指定的设备或文件。系统默认从显示器读取输入信息。
重定向使用举例:
=========================================
@echo off
echo abcdefg——这是文件a.txt中的信息>a.txt
echo 请任意输入字符,以回车结束:
set /p ifo=
cls
echo 【 从屏幕获得的输入信息 】
echo %ifo%
set /p ifo=<a.txt
echo 【 从文件a.txt获得的输入信息 】
echo %ifo%
pause
=========================================

管道符号 |

前一个命令的执行结果输出到后一个命令
dir *.* /s/a | find /c ".exe"管道命令表示先执行 dir 命令,对其输出的结果执行后面的 find 命令该命令行结果:
输出当前文件夹及所有子文件夹里的.exe文件的个数

转义符 ^

将特殊符号转化为一般符号,即剥离特殊符号的特殊地位。特殊符号指:| & > <
比如,如果我们想输出符号“>”,直接用命令 echo > 是不行的,必须修改为 echo ^> 。其余几个特殊符号类似需要有同样的处理。
转义字符使用举例:
=========================================
@echo off
echo aaaa>a.txt
echo 第一句echo执行完毕
echo aaaa^>a.txt
echo 第二句echo执行完毕
pause
=========================================
比较上面的两句echo,第一句echo将信息aaaa输出到了文件a.txt,而第二句echo则在直接屏幕上显示除aaaa>a.txt

逻辑命令符包括:&、&&、||

-&顺序执行多条命令,而不管命令是否执行成功
    c: & cd/ & dir /w相当于把下面3行命令写到1行去了c:cd/dir /w
-&&顺序执行多条命令,当碰到执行出错的命令后将不执行后面的命令
    f: && cd/ && dir >c:/test.txt注意如果f盘不存在,那么后面2条命令将不会执行
    find "ok" c:/test.txt && echo 成功如果找到了"ok"字样,就显示"成功",找不到就不显示
-||顺序执行多条命令,当碰到执行正确的命令后将不执行后面的命令
    find "ok" c:/test.txt || echo 不成功如果找不到"ok"字样,就显示"不成功",找到了就不显示
  • 批处理命令简介

echo

echo 和 @
回显命令
@                     #关闭单行回显
echo off              #从下一行开始关闭回显
@echo off             #从本行开始关闭回显。一般批处理第一行都是这个
echo on               #从下一行开始打开回显
echo                  #显示当前是 echo off 状态还是 echo on 状态
echo.                 #输出一个”回车换行”,空白行

errorlevel

echo %errorlevel%
每个命令运行结束,可以用这个命令行格式查看返回码
默认值为0,一般命令执行出错会设 errorlevel 为1
带选择的命令后可接受命令代码,参看choice例子

rem

rem 和 ::
注释命令
注释行不执行操作

pause

暂停命令。运行 Pause 命令时,将显示下面的消息:Press any key to continue. . .(或:请按任意键继续. . .)
===========================================
@echo off
:begin
copy G:*.* d:/back
echo 请插入另一张光盘...
pause
goto begin
============================================
在这个例子中,驱动器 G 中磁盘上的所有文件均复制到d:/back中。显示的注释提示您将另一张光盘盘放入驱动器 G 时,pause 命令会使程序挂起,以便您更换光盘,然后按任意键继续处理。

call

从一个批处理程序调用另一个批处理程序,并且不终止父批处理程序。call 命令接受用作调用目标的标签。如果在脚本或批处理文件外使用 Call,它将不会在命令行起作用。
call [[Drive:][Path] FileName ] [:label [arguments]]
call test.bat //调用另一个bat文件
===========================================
@ echo off  
call :label  
echo 1  
echo 2  
:label  
echo 3  
echo 4  
===========================================
首先,我们看到,用call的时候,label前面的:不能丢掉,否则错误(当然,对于goto而言,你也可以加上:)。
另外,结果也不同,用call的时候结果为:341234
可以看到,goto很单纯,直接Go to 到了某地方,而call则有点调用的意味,所以, goto 和call的还是有区别的。

start

调用外部程序,所有的DOS命令和命令行程序都可以由start命令来调用。 如:start calc.exe 即可打开Windows的计算器。

goto

goto 和 :
跳转命令。程序指针跳转到指定的标签,从标签后的第一条命令开始继续执行批处理程序。
:label         #行首为:表示该行是标签行,标签行不执行操作
goto label     #跳转到指定的标签那一行

set

显示、设置或删除变量。
显示变量:set 或 set s 前者显示批处理当前已定义的所有变量及其值,后者显示所有以s开头的变量及值。
设置变量:set aa=abcd 此句命令便可向变量aa赋值abcd。
如果变量aa已被定义,则aa的值被修改为abcd;若aa尚未定义,则此句命令即可定义新的变量aa,同时为变量aa赋予初始值abcd。
删除变量:set aa= 此句命令即可删除变量aa。若变量aa已被定义,则删除变量aa;若aa尚未定义,则此句命令为实质意义。
需要说明的是,批处理中的变量是不区分类型的,不需要像C语言中的变量那样还要区分int、float、char等。比如执行set aa=345后,变量aa的值既可以被视为数字345,也可以被视为字符串345。
set命令具有扩展功能,如用作交互输入、字符串处理、数值计算等,属于高级命令范畴。

%0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*命令行传递给批处理的参数

%0 批处理文件本身
%1 第一个参数
%9 第九个参数
%* 从第一个参数开始的所有参数
批参数(%n)的替代已被增强。您可以使用以下语法
     %~1          - 删除引号("),扩充 %1
     %~f1         - 将 %1 扩充到一个完全合格的路径名
     %~d1         - 仅将 %1 扩充到一个驱动器号
     %~p1         - 仅将 %1 扩充到一个路径
     %~n1         - 仅将 %1 扩充到一个文件名
     %~x1         - 仅将 %1 扩充到一个文件扩展名
     %~s1         - 扩充的路径指含有短名
     %~a1         - 将 %1 扩充到文件属性
     %~t1         - 将 %1 扩充到文件的日期/时间
     %~z1         - 将 %1 扩充到文件的大小
     %~$PATH : 1 - 查找列在 PATH 环境变量的目录,并将 %1
                   扩充到找到的第一个完全合格的名称。如果环境
                   变量名未被定义,或者没有找到文件,此组合键会
                   扩充到空字符串
可以组合修定符来取得多重结果:
    %~dp1        - 只将 %1 扩展到驱动器号和路径
    %~nx1        - 只将 %1 扩展到文件名和扩展名
    %~dp$PATH:1 - 在列在 PATH 环境变量中的目录里查找 %1,
                   并扩展到找到的第一个文件的驱动器号和路径。
    %~ftza1      - 将 %1 扩展到类似 DIR 的输出行。
可以参照 call/? 或 for/? 看出每个参数的含意
echo load "%%1" "%%2">c:test.txt
生成的文件内容为 load "%1" "%2"
批处理文件里,用这个格式把命令行参数输出到文件
==============================================
在C盘根目录新建test.bat,内容如下:
@echo off
echo %0
echo %1
echo %2
echo %*
运行cmd,输入 c:/test.bat "/a" /b /c /d,可以看出每个参数的含意 修改test.bat内容如下
@echo off
echo %1
echo %~1
echo %0
echo %~f0
echo %~d0
echo %~p0
echo %~n0
echo %~x0
echo %~s0
echo %~a0
echo %~t0
echo %~z0
再运行cmd,输入 c:/test.bat "/a" /b /c /d可以参照 call/? 或 for/? 看出每个参数的含意,注意这里可以对文件进行日期比较和大小比较:
echo load "%%1" "%%2">c:/test.txt
==============================================

set设置变量

设置变量
引用变量可在变量名前后加 % ,即 %变量名%
set                     #显示目前所有可用的变量,包括系统变量和自定义的变量
echo %SystemDrive%      #显示系统盘盘符。系统变量可以直接引用
set p                   #显示所有以p开头的变量,要是一个也没有就设errorlevel=1
set p=aa1bb1aa2bb2      #设置变量p,并赋值为 = 后面的字符串,即aa1bb1aa2bb2
echo %p%                #显示变量p代表的字符串,即aa1bb1aa2bb2
echo %p:~6%             #显示变量p中第6个字符以后的所有字符,即aa2bb2
echo %p:~6,3%           #显示第6个字符以后的3个字符,即aa2
echo %p:~0,3%           #显示前3个字符,即aa1
echo %p:~-2%            #显示最后面的2个字符,即b2
echo %p:~0,-2%          #显示除了最后2个字符以外的其它字符,即aa1bb1aa2b
echo %p:aa=c%           #用c替换变量p中所有的aa,即显示c1bb1c2bb2
echo %p:aa=%            #将变量p中的所有aa字符串置换为空,即显示1bb12bb2
echo %p:*bb=c%          #第一个bb及其之前的所有字符被替换为c,即显示c1aa2bb2
set p=%p:*bb=c%         #设置变量p,赋值为 %p:*bb=c% ,即c1aa2bb2
set /a p=39             #设置p为数值型变量,值为39
set /a p=39/10          #支持运算符,有小数时用去尾法,39/10=3.9,去尾得3,p=3
set /a p=p/10           #用 /a 参数时,在 = 后面的变量可以不加%直接引用
set /a p=”1&0″          #”与”运算,要加引号。其它支持的运算符参见set/?
set p=                  #取消p变量
set /p p=请输入
屏幕上显示”请输入”,并会将输入的字符串赋值给变量p
注意这条可以用来取代 choice 命令
注意变量在 if 和 for 的复合语句里是一次性全部替换的,如
@echo off
set p=aaa
if %p%==aaa (
     echo %p%
     set p=bbb
     echo %p%
     )
结果将显示
aaa
aaa
因为在读取 if 语句时已经将所有 %p% 替换为aaa
这里的"替换",在 /? 帮助里就是指"扩充"、"环境变量扩充"
可以启用”延缓环境变量扩充”,用 ! 来引用变量,即 !变量名!
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set p=aaa
if %p%==aaa (
     echo %p%
     set p=bbb
     echo !p!
     )
ENDLOCAL
结果将显示
aaa
bbb
还有几个动态变量,运行 set 看不到
%CD%                   #代表当前目录的字符串
%DATE%                 #当前日期
%TIME%                 #当前时间
%RANDOM%               #随机整数,介于0~32767
%ERRORLEVEL%           #当前 ERRORLEVEL 值
%CMDEXTVERSION%        #当前命令处理器扩展名版本号
%CMDCMDLINE%           #调用命令处理器的原始命令行
可以用echo命令查看每个变量值,如 echo %time%
注意 %time% 精确到毫秒,在批处理需要延时处理时可以用到

choice 语句

@echo off
rem 以下在win2000pro运行通过,从win98里拷的chioce.com文件
choice /c:abc
if errorlevel 3 goto ccc
if %errorlevel%==2 goto bbb
if errorlevel==1 goto aaa
rem 必须先判断数值高的返回码rem 可以看到 errorlevel 值的判断有3种写法,有时某种写法不好用,可以用另外的写法
:aaa
echo aaa
goto end
:bbb
echo bbb
goto end
:ccc
echo ccc
goto end
:end

assoc 和 ftype文件关联

assoc 和 ftype文件关联assoc 设置'文件扩展名'关联,关联到'文件类型'ftype 设置'文件类型'关联,关联到'执行程序和参数'当你双击一个.txt文件时,windows并不是根据.txt直接判断用 notepad.exe 打开而是先判断.txt属于 txtfile '文件类型'再调用 txtfile 关联的命令行 txtfile=%SystemRoot%/system32/NOTEPAD.EXE %1可以在"文件夹选项"→"文件类型"里修改这2种关联
assoc           #显示所有'文件扩展名'关联
assoc .txt      #显示.txt代表的'文件类型',结果显示 .txt=txtfile
assoc .doc      #显示.doc代表的'文件类型',结果显示 .doc=Word.Document.8
assoc .exe      #显示.exe代表的'文件类型',结果显示 .exe=exefile
ftype           #显示所有'文件类型'关联
ftype exefile   #显示exefile类型关联的命令行,结果显示 exefile="%1" %* assoc .txt=Word.Document.8设置.txt为word类型的文档,可以看到.txt文件的图标都变了
assoc .txt=txtfile恢复.txt的正确关联 ftype exefile="%1" %*恢复 exefile 的正确关联
如果该关联已经被破坏,可以运行 command.com ,再输入这条命令

pushd 和 popd切换当前目录

@echo off
c: & cd/ & md mp3       #在 C:/ 建立 mp3 文件夹
md d:/mp4               #在 D:/ 建立 mp4 文件夹
cd /d d:/mp4            #更改当前目录为 d:/mp4
pushd c:/mp3            #保存当前目录,并切换当前目录为 c:/mp3
popd                    #恢复当前目录为刚才保存的 d:/mp4一般用处不大,在当前目录名不确定时,会有点帮助

subst (外部命令)映射磁盘

subst z: //server/d     #这样输入z:就可以访问//server/d了
subst z: /d             #取消该映射
subst                   #显示目前所有的映

if

判断命令
if "%1"=="/a" echo 第一个参数是/a
if /i "%1" equ "/a" echo 第一个参数是/a
/i 表示不区分大小写,equ 和 == 是一样的,其它运算符参见 if/?
if exist c:test.bat echo 存在c:test.bat文件
if not exist c:windows (
     echo 不存在c:windows文件夹
     )
if exist c:test.bat (
     echo 存在c:test.bat
     ) else (
     echo 不存在c:test.bat
     )

setlocal 和 endlocal

设置”命令扩展名”和”延缓环境变量扩充”
SETLOCAL ENABLEEXTENSIONS             #启用"命令扩展名"
SETLOCAL DISABLEEXTENSIONS            #停用"命令扩展名"
SETLOCAL ENABLEDELAYEDEXPANSION       #启用"延缓环境变量扩充"
SETLOCAL DISABLEDELAYEDEXPANSION      #停用"延缓环境变量扩充"
ENDLOCAL                              #恢复到使用SETLOCAL语句以前的状态
“命令扩展名”默认为启用
“延缓环境变量扩充”默认为停用
批处理结束系统会自动恢复默认值
可以修改注册表以禁用"命令扩展名",详见 cmd /? 。所以用到"命令扩展名"的程
序,建议在开头和结尾加上 SETLOCAL ENABLEEXTENSIONS 和 ENDLOCAL 语句,以确
保程序能在其它系统上正确运行
"延缓环境变量扩充"主要用于 if 和 for 的符合语句,在 set 的说明里有其实用例程

for

循环命令
这个比较复杂,请对照 for/? 来看
for %%i in (c: d: e: f:) do echo %%i
依次调用小括号里的每个字符串,执行 do 后面的命令
注意%%i,在批处理中 for 语句调用参数用2个%
默认的字符串分隔符是"空格键","Tab键","回车键"
for %%i in (*.txt) do find "abc" %%i
对当前目录里所有的txt文件执行 find 命令
for /r . %%i in (*.txt) do find "abc" %%i
在当前目录和子目录里所有的.txt文件中搜索包含 abc 字符串的行
for /r . %%i in (.) do echo %%~pni
显示当前目录名和所有子目录名,包括路径,不包括盘符
for /r d:mp3 %%i in (*.mp3) do echo %%i>>d:mp3.txt
把 d:mp3 及其子目录里的mp3文件的文件名都存到 d:mp3.txt 里去
for /l %%i in (2,1,8) do echo %%i
生成2345678的一串数字,2是数字序列的开头,8是结尾,1表示每次加1
for /f %%i in ('set') do echo %%i
对 set 命令的输出结果循环调用,每行一个
for /f "eol=P" %%i in ('set') do echo %%i
取 set 命令的输出结果,忽略以 P 开头的那几行
for /f %%i in (d:mp3.txt) do echo %%i
显示 d:mp3.txt 里的每个文件名,每行一个,不支持带空格的名称
for /f "delims=" %%i in (d:mp3.txt) do echo %%i
显示 d:mp3.txt 里的每个文件名,每行一个,支持带空格的名称
for /f "skip=5 tokens=4" %%a in ('dir') do echo %%a
对 dir 命令的结果,跳过前面5行,余下的每行取第4列
每列之间的分隔符为默认的"空格"
可以注意到 dir 命令输出的前5行是没有文件名的
for /f "tokens=1,2,3 delims=- " %%a in ('date /t') do (
     echo %%a
     echo %%b
     echo %%c
     )
对 date /t 的输出结果,每行取1、2、3列
第一列对应指定的 %%a ,后面的 %%b 和 %%c 是派生出来的,对应其它列
分隔符指定为 - 和"空格",注意 delims=- 后面有个"空格"
其中 tokens=1,2,3 若用 tokens=1-3 替换,效果是一样的
for /f "tokens=2* delims=- " %%a in ('date /t') do echo %%b
取第2列给 %%a ,其后的列都给 %%b

xcopy (外部命令)

文件拷贝
xcopy d:mp3 e:mp3 /s/e/i/y
复制 d:mp3 文件夹、所有子文件夹和文件到 e: ,覆盖已有文件
加 /i 表示如果 e: 没有 mp3 文件夹就自动新建一个,否则会有询问

推荐阅读更多精彩内容

  • 个人学习批处理的初衷来源于实际工作;在某个迭代版本有个BS(安卓手游模拟器)大需求,从而在测试过程中就重复涉及到...
    Luckykailiu阅读 2,776评论 0 11
  • 基础命令 主要的命令和快捷键 Linux系统命令由三部分组成:cmd + [options]+[operation...
    守护者20091776阅读 545评论 0 0
  • Windows下不区分大小写! Batch: batch -- 批处理;batch file -- 批处理文件;D...
    Zhang21阅读 2,033评论 0 5
  • 最近初略的看完了《批处理标准教程-MHL版本》,把教程中的一些对我有帮助的资料转为MD格式,就当是做个笔记,加深记...
    禾白小三飘阅读 805评论 1 6
  • 终于明白,刘德华唱出的《忘情水》是怎样的一种意境。如果有,也请你给我一杯。若不能相濡以沫,不得长相厮守,便祈求索性...
    见玉阅读 39评论 0 1