END属性常用来构建动态的单元格范围，获取有效的数据区域。
- 其写法是
单元格.end(方向)
- 要构建一个行数不断增加的动态单元格范围，如下面代码
Sub 动态单元格()
Dim 最后一行 As Long, 最后一行1 As Long
Dim rng As Range, rng1 As Range
最后一行 = Range("a1").End(xlDown).Row
最后一行1 = Range("a13").End(xlUp).Row
Set rng = Range("a1:c" & 最后一行)
Debug.Print "rng的单元格范围是" & rng.Address
Set rng1 = Range("a1:c" & 最后一行1)
Debug.Print "rng1的单元格范围是" & rng1.Address
End Sub
最后一行 = Range("a1").End(xlDown).Row
从A2（A1不算）开始在A列向下xlDown查找 ‘连续’ 不为空的单元格，
一旦遇到空单元格则停止，返回最后一个非空单元格（地址）。
最后一行1 = Range("a13").End(xlUp).Row
从A12（A13不算）开始在A列向上xlUp查找不为空的单元格，
过程中遇到不为空单元格则停止，返回不为空单元格的（地址）。
- end(xldown)查找演示（遇空则停）
- end(xlup)同理,换个方向而已（找到非空为止）。
-
假如A5单元格变为空单元格，则上面两个end返回不同的行号。
- 当行数增加后，再运行代码
- 注意红色方框中的Range("a65535")，通常使用end(xlup)时，会设置一个比大的单元格作为起始点。
-03版的的excel有65536行。
-07版以上的excel有1048576行。
-因此，如果Range("a1048576").end(xlup)这种写法在03版是报错的，因为03excel不支持那么大的行数。 - 解决方法是下面的这种写法
Cells(Rows.Count, 1).End(xlUp).Row
- 如果是03版excel，则rows.count是65536,07版以上1048576.
- 如指定单元格区域，则rows.count返回该单元格区域的行数。
- END除了xlup，xldown，还有xltoleft（向左），xltoright（向右）两个方向的查找，原理都一样，通常用来确定动态单元格范围的列数。
- 练习:动态的高级筛选：根据部门筛选
- 先录制高级筛选的宏，得出这样的代码。
Sub 宏2()
Application.CutCopyMode = False
Application.CutCopyMode = False
Sheets("Sheet4").Range("A1:C13").AdvancedFilter Action:=xlFilterCopy, _
CriteriaRange:=Range("A1:A2"), CopyToRange:=Range("A4"), Unique:=False
End Sub
- 将代码改为动态的单元格区域，将筛选结果放到另外的工作表。
-
1、用End属性构建动态的单元格区域。很少的改动就可以实现动态高级筛选。
Paste_Image.png
Sub 宏2()
Dim LastRow As Long
LastRow = Sheets("sheet4").Cells(Rows.Count, 1).End(xlUp).Row '动态获取数据行数
Sheets("Sheet4").Range("A1:C" & LastRow).AdvancedFilter Action:=xlFilterCopy, _
CriteriaRange:=Sheets("sheet1").Range("A1:A2"), CopyToRange:=Sheets("sheet1").Range("A4"), Unique:=False
End Sub
- 代码效果演示如下。稍稍修改，高级筛选就方便如意。
