来自于宏的黑魔法 --- 简单实现面向切面编程

Elixir Macro AOP 面向切面 元编程


什么是 AOP (面向切面编程)?

面向切面编程 AOP(Aspect Oriented Programming) 是什么?简单来讲,就是把某些流程逻辑提取出来,然后用一种非侵入式的写法把这个逻辑加到其它某个逻辑上去。
听起来还是很绕?没关系,我们来看一些例子来帮助我们理解。

打印日志

日志可以说是 AOP 的典型应用之一。
假如我们需要打印某个函数的返回值,我们先看看没有用 AOP 之前代码应该怎么写。

# 两个数的加法运算
def plus(a, b) do
  result = a + b

  # 在控制台打印返回值,并返回 result 作为返回值
  IO.inspect(result)
end

看起来很简单对吧?但是如果我们有几十个函数需要增加打印返回值的功能,那我们只能添加几十遍了。你可能觉得这样还好,累就累吧。那现在又来了新需求,要求要在打印之前增加一个提示信息,就像这样

# 两个数的加法运算
def plus(a, b) do
  result = a + b

  # 在控制台打印
  IO.inspect("WARNING: #{result}")
  # 并返回 result 作为返回值
  result
end

总不能几十个数每个再改一遍吧???

函数式解决方案

由于有了函数式强大的表达能力,我们很自然的就想到用高阶函数来封装这个逻辑。就像这样

def my_logger(fun) do
  result = fun.()

  IO.inspect("WARNING: #{result}")
  result
end

def plus(a, b) do
  a + b
end

def sub(a, b) do
  a - b
end

# 用的时候这么用
my_logger(fn() -> plus(1, 2) end)
my_logger(fn() -> sub(2, 1) end)

这样也太麻烦了吧,而且需要改变调用的方式,非常麻烦。

AOP 登场

假如我只需要声明一下某个方法需要打印日志,它就能打印,岂不美哉?
如果 Elixir 有 logger 功能就好了。
还在苦苦等待官方来增加新特性么?不要再等啦!立即拿起宏武器,马上开始自己创造语法糖吧!

# defmodule 是 Elixir 中的命名空间。相当于 Java 的 package
defmodule EnhanceElixir do
  defmacro deflog(args, do: block) do
    quote do
      def unquote(args) do
        result = unquote(block)

        IO.inspect("WARNING: #{result}")
        result
      end
    end
  end
end

defmodule Test do
  require EnhanceElixir

  # 只需把 def 换成 EnhanceElixir.deflog,黑魔法就生效啦~
  EnhanceElixir.deflog plus(a, b) do
    a + b
  end
end

# 调用方无需做出改变
Test.plus(1, 2)

deflog 宏到底是怎么工作的呢?现在就来分析一下。
在理解这段代码之前,我先用不严谨但是更容易理解的话来解释宏是个什么。
在 Elixir 里写宏,通常只需要注意三个关键字:defmacro quote unquotedefmacro 顾名思义就用它来定义一个宏,用法看起来非常像用来定义函数的 def。那它和函数比起来有什么不同呢?最大的不同就是执行的时机不同,宏是在编译的时候执行的,而函数是在运行的时候执行的。宏在执行的时候像是对我们的源代码进行了一些修修补补,它操作的是“源代码”。可以说宏是操作代码的代码,大家称这种用代码来操作代码的编程方式为“元编程”。那如何去操作代码呢?
简单来说,宏很像是一种模板,写过模板语言的同学估计很容易理解,我们把没有动态能力的文本(比如HTML)中插入一些标记,然后用其它语言去操作这些文本,比如插入,循环,逻辑判断等。最后生成出一个处理完毕之后的文本,就可以实现各种效果了。但宏又和模板有本质区别,模板说到底是在处理字符串文本,而并没有真正解析文本结构,比如 jsp 并没有去解析 HTML DOM 节点,而宏确可以把代码真正的解析成抽象语法树(AST),这就让宏获得了接近语言极限的表达能力。当然本文没有用到这部分功能,仅仅把它理解成一个模板就足够了。
在 Elixir 中,使用 quote 就可以让一段代码变成“模板”(AST)。宏里面写的代码并不会被直接执行,而是在编译时期在调用该宏的地方,将这些由 quote 生成的“模板”插入到对应位置。这个过程被称为“宏展开”。

知道这些之后,我们回过头来分析一下打印日志的需求,提取出其中的“模板”(通用部分)。

def {这里填函数名} do
  result = {这里是函数执行体}

  IO.inspect("WARNING: #{result}")
  result
end

打印日志的需求其实就是这样,很清晰不是么。现在的问题是,怎么用宏来把代码填入到对应位置呢。
首先,用 quote 包裹

quote do
  def {这里填方法名和参数} do
    result = {这里是方法执行体}

    IO.inspect("WARNING: #{result}")
    result
  end
end

那这些函数名函数体什么的怎么传过去呢?可以通过 defmacro 的参数传递进来。

defmacro deflog(args, do: block) do
  quote do
    def {这里填方法名和参数} do
      result = {这里是方法执行体}

      IO.inspect("WARNING: #{result}")
      result
    end
  end
end

这样,在调用 deflog 的时候,它后面的方法名和参数就会被传到 args,它的 do end 代码块里的代码就会被传到 do: block 里的 block 参数中。
那直接把 argblock 填在相应位置就行了?不行。还记得之前说的 quote 里的代码其实被转成了语法树么,如果直接填写就会被当做一个普通的值并不会被解释成参数。
如果你想要执行动态的代码,而不是把代码转成语法树,那你就需要用 unquote 了。所以最终代码就变成了这样。

defmacro deflog(args, do: block) do
  quote do
    def unquote(args) do
      result = unquote(block)

      IO.inspect("WARNING: #{result}")
      result
    end
  end
end

我们还可以使用 import 功能,在调用的时候不需要加上命名空间,这样我们自创的语法糖用起来就更像原生功能了。

import EnhanceElixir

# 只需把 def 换成 deflog,黑魔法就生效啦~
deflog plus(a, b) do
  a + b
end

是不是就像 Elixir 自带功能一样好用?

更进一步

如果我们希望具体打印的方法也可以配置呢?
宏里面可以继续套宏,在展开的时候则会一层一层的展开。这个功能就留给感兴趣的同学自己实现啦。


结语

Elixir 语言并没有提供原生的 AOP 语法,但是藉由宏这种强大的武器,我们就可以用它制造自己的语法糖,实现新特性,来最大程度的降低代码冗余。
但宏也是把双刃剑,由于其过于强大,如果设计不当,那么调用者可能很难预估宏调用所带来的影响。
本例中的 AOP 还有许多限制,不够灵活,实际使用中还需稍加改造。但表述的思想大致是相同的。
最后,不论何种思想,何种姿势,最终目的都是为了减少代码冗余,降低代码耦合,提高可维护性。从源头上理解技术要解决的问题,才能真正理解技术。


推荐阅读更多精彩内容