Gradle实现统一依赖管理

目的

在版本迭代过程中，经常遇到一种情况: 一旦android SDK、android support包，gradle build tool以及一些第三方包一旦推出新版本，为了保持新特性的支持，我们需要对每个module中的build.gradle文件都进行一次手动修改，费时又费力。

分配属性配置

• 在项目的根目录创建一个gradle配置文件config.gradle(名字任意)，项目中所有的依赖只要在这个文件中统一配置即可。格式如下(内容根据需要可以进行修改)

ext {
    android = [
            applicationId    : "com.wm.kotlin_wanandroid",
            compileSdkVersion: 28,
            minSdkVersion    : 19,
            targetSdkVersion : 28,
            versionCode      : 1,
            versionName      : "1.0"
    ]

    dependencies = [
            "appcompat"       : 'androidx.appcompat:appcompat:1.1.0',
            "core"            : 'androidx.core:core-ktx:1.1.0',
            "constraintlayout": 'androidx.constraintlayout:constraintlayout:1.1.3',
            "lottie": 'com.airbnb.android:lottie:3.2.2'
    ]

}

• 其次在根目录的build.gradle文件中添加内容(apply from: "config.gradle")，所有的module都可以从这个(config.gradle)配置文件里读取公共参数。

apply from: "config.gradle"
buildscript {
    ext.kotlin_version = '1.3.50'
    repositories {
        google()
        jcenter()
        
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.5.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        jcenter()
        
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

• 在各个module目录下的build.gradle文件中使用如下:

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'

android {
    compileSdkVersion rootProject.ext.android.compileSdkVersion
    defaultConfig {
        applicationId rootProject.ext.android.applicationId
        minSdkVersion rootProject.ext.android.minSdkVersion
        targetSdkVersion rootProject.ext.android.targetSdkVersion
        versionCode rootProject.ext.android.versionCode
        versionName rootProject.ext.android.versionName
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    api rootProject.ext.dependencies['appcompat']
    api rootProject.ext.dependencies['core']
    api rootProject.ext.dependencies['constraintlayout']
    api rootProject.ext.dependencies['lottie']
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'androidx.test.ext:junit:1.1.1'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.2.0'
}