Groovy与Java的差异

http://groovy-lang.org/differences.html

Groovy尝试使Java开发人员尽可能自然。在设计Groovy时,我们一直尝试遵循最少惊奇的原则,特别是对于那些学习过Java背景的Groovy的开发人员。

在这里,我们列出了Java与Groovy之间的所有主要区别。

1.默认导入

默认情况下,所有这些包和类都是导入的,即,您不必使用显式import语句来使用它们:

java.io.*
java.lang.*
java.math.BigDecimal
java.math.BigInteger
java.net.*
java.util.*
groovy.lang.*
groovy.util.*

2.多种方法

在Groovy中,将在运行时选择要调用的方法。这称为运行时调度或多方法。这意味着将在运行时根据参数的类型选择方法。在Java中,情况恰恰相反:方法是在编译时根据声明的类型选择的。

以下用Java代码编写的代码可以在Java和Groovy中进行编译,但是它们的行为有所不同:

int method(String arg) {
    return 1;
}
int method(Object arg) {
    return 2;
}
Object o = "Object";
int result = method(o);

在Java中,您将拥有:

assertEquals(2, result);

而在Groovy中:

assertEquals(1, result);

这是因为Java将使用静态信息类型,该类型o被声明为Object,而Groovy将在运行时选择实际调用该方法的时间。由于它是带一个String,那么 String版本被调用。

3.数组初始化器

在Groovy中,{ …​ }块保留用于闭包。这意味着您不能使用以下语法创建数组文字:

int[] array = { 1, 2, 3}

实际上必须使用:

int[] array = [1,2,3]

4.包范围可见性

在Groovy中,在字段上省略修饰符不会像Java中那样导致package-private字段:

class Person {
    String name
}

相反,它用于创建属性,即私有字段,关联的getter和关联的 setter。

可以通过以下方式创建一个package-private字段@PackageScope:

class Person {
    @PackageScope String name
}

5. ARM块

Groovy不支持Java 7的ARM(自动资源管理)块。相反,Groovy提供了各种依赖于闭包的方法,这些闭包具有相同的效果,但更加惯用。例如:

Path file = Paths.get("/path/to/file");
Charset charset = Charset.forName("UTF-8");
try (BufferedReader reader = Files.newBufferedReader(file, charset)) {
    String line;
    while ((line = reader.readLine()) != null) {
        System.out.println(line);
    }

} catch (IOException e) {
    e.printStackTrace();
}

可以这样写:

new File('/path/to/file').eachLine('UTF-8') {
   println it
}

或者,如果您想要一个更接近Java的版本:

new File('/path/to/file').withReader('UTF-8') { reader ->
   reader.eachLine {
       println it
   }
}

6.内部类

匿名内部类和嵌套类的实现遵循Java的原则,groovy.lang.Closure的实现看起来很像我们要做的事情,有一些好处,也有一些区别。例如,访问私有字段和方法可能会成为一个问题,但另一方面,局部变量不一定必须是Final变量。

6.1 静态内部类

这是静态内部类的示例:

class A {
    static class B {}
}

new A.B()

静态内部类的使用是最受支持的一种。如果您绝对需要一个内部类,则应使其成为静态类。

6.2 匿名内部类

import java.util.concurrent.CountDownLatch
import java.util.concurrent.TimeUnit

CountDownLatch called = new CountDownLatch(1)

Timer timer = new Timer()
timer.schedule(new TimerTask() {
    void run() {
        called.countDown()
    }
}, 0)

assert called.await(10, TimeUnit.SECONDS)

6.3 非静态内部类的实例

在Java中,您可以执行以下操作:

public class Y {
    public class X {}
    public X foo() {
        return new X();
    }
    public static X createX(Y y) {
        return y.new X();
    }
}

Groovy不支持y.new X()语法。相反,您必须编写new X(y),如下面的代码所示:

public class Y {
    public class X {}
    public X foo() {
        return new X()
    }
    public static X createX(Y y) {
        return new X(y)
    }
}

但是请注意,Groovy支持使用一个参数调用方法而无需给出参数。该参数的值将为null。基本上,相同的规则适用于调用构造函数。

7. Lambdas

Java 8支持lambda和方法引用:

Runnable run = () -> System.out.println("Run");
list.forEach(System.out::println);

Java 8 lambda或多或少可被视为匿名内部类。Groovy不支持该语法,但是具有闭包:

Runnable run = { println 'run' }
list.each { println it } // or list.each(this.&println)

8. GStrings

由于将双引号字符串文字解释为GString值,如果String使用Groovy和Java编译器编译文字文字包含美元字符的类,则Groovy可能会因编译错误而失败或产生微妙的不同代码。

通常,Groovy将自动在GString,String之间进行广播。如果API声明了参数的类型,请当心接受Object参数的Java API,然后检查实际类型。

9.字符串和字符文字

在Groovy单引号的文字被用于String。双引号的结果是String还是GString取决于是否有字面插值。

assert 'c'.getClass()==String
assert "c".getClass()==String
assert "c${1}".getClass() in GString

Groovy 仅在分配给type变量时才会自动将单个字符String转换为char。当使用类型为实参的方法调用方法时,我们需要显式转换或确保值已预先转换char。

char a='a'
assert Character.digit(a, 16)==10 : 'But Groovy does boxing'
assert Character.digit((char) 'a', 16)==10

try {
  assert Character.digit('a', 16)==10
  assert false: 'Need explicit cast'
} catch(MissingMethodException e) {
}

Groovy支持两种类型的转换,在字符串转换多个char字符时,在转换的情况下存在细微的差异。Groovy样式的转换更宽容,将采用第一个字符,而C样式的转换将异常失败。

// for single char strings, both are the same
assert ((char) "c").class==Character
assert ("c" as char).class==Character

// for multi char strings they are not
try {
  ((char) 'cx') == 'c'
  assert false: 'will fail - not castable'
} catch(GroovyCastException e) {
}
assert ('cx' as char) == 'c'
assert 'cx'.asType(char) == 'c'

10.基元和包装

因为Groovy对所有内容都使用对象,所以它会自动包装对基元的引用。因此,它不遵循Java的扩展行为,即优先于装箱。这是一个使用示例int

int i
m(i)

void m(long l) {         // 1  
  println "in m(long)"
}

void m(Integer i) {        // 2
  println "in m(Integer)"
}

1是Java会调用的方法,因为扩展优先于拆箱。
2是Groovy实际调用的方法,因为所有原始引用都使用其包装器类。

11.==行为

Java用 ==表示对象的原始类型或身份相等。在Groovy ==转换到a.equals(b)或者a.compareTo(b)==0,如果他们是Comparable。要检查身份,有is。例如 a.is(b)。

13.额外关键字

Groovy中的关键字比Java中的关键字多。不要将它们用于变量名等。

  • as
  • def
  • in
  • trait
©著作权归作者所有,转载或内容合作请联系作者
  • 序言:七十年代末,一起剥皮案震惊了整个滨河市,随后出现的几起案子,更是在滨河造成了极大的恐慌,老刑警刘岩,带你破解...
    沈念sama阅读 151,688评论 1 330
  • 序言:滨河连续发生了三起死亡事件,死亡现场离奇诡异,居然都是意外死亡,警方通过查阅死者的电脑和手机,发现死者居然都...
    沈念sama阅读 64,559评论 1 273
  • 文/潘晓璐 我一进店门,熙熙楼的掌柜王于贵愁眉苦脸地迎上来,“玉大人,你说我怎么就摊上这事。” “怎么了?”我有些...
    开封第一讲书人阅读 101,749评论 0 226
  • 文/不坏的土叔 我叫张陵,是天一观的道长。 经常有香客问我,道长,这世上最难降的妖魔是什么? 我笑而不...
    开封第一讲书人阅读 42,581评论 0 191
  • 正文 为了忘掉前任,我火速办了婚礼,结果婚礼上,老公的妹妹穿的比我还像新娘。我一直安慰自己,他们只是感情好,可当我...
    茶点故事阅读 50,741评论 3 271
  • 文/花漫 我一把揭开白布。 她就那样静静地躺着,像睡着了一般。 火红的嫁衣衬着肌肤如雪。 梳的纹丝不乱的头发上,一...
    开封第一讲书人阅读 39,684评论 1 192
  • 那天,我揣着相机与录音,去河边找鬼。 笑死,一个胖子当着我的面吹牛,可吹牛的内容都是我干的。 我是一名探鬼主播,决...
    沈念sama阅读 31,122评论 2 292
  • 文/苍兰香墨 我猛地睁开眼,长吁一口气:“原来是场噩梦啊……” “哼!你这毒妇竟也来了?” 一声冷哼从身侧响起,我...
    开封第一讲书人阅读 29,847评论 0 182
  • 序言:老挝万荣一对情侣失踪,失踪者是张志新(化名)和其女友刘颖,没想到半个月后,有当地人在树林里发现了一具尸体,经...
    沈念sama阅读 33,441评论 0 228
  • 正文 独居荒郊野岭守林人离奇死亡,尸身上长有42处带血的脓包…… 初始之章·张勋 以下内容为张勋视角 年9月15日...
    茶点故事阅读 29,939评论 2 232
  • 正文 我和宋清朗相恋三年,在试婚纱的时候发现自己被绿了。 大学时的朋友给我发了我未婚夫和他白月光在一起吃饭的照片。...
    茶点故事阅读 31,333评论 1 242
  • 序言:一个原本活蹦乱跳的男人离奇死亡,死状恐怖,灵堂内的尸体忽然破棺而出,到底是诈尸还是另有隐情,我是刑警宁泽,带...
    沈念sama阅读 27,783评论 2 236
  • 正文 年R本政府宣布,位于F岛的核电站,受9级特大地震影响,放射性物质发生泄漏。R本人自食恶果不足惜,却给世界环境...
    茶点故事阅读 32,275评论 3 220
  • 文/蒙蒙 一、第九天 我趴在偏房一处隐蔽的房顶上张望。 院中可真热闹,春花似锦、人声如沸。这庄子的主人今日做“春日...
    开封第一讲书人阅读 25,830评论 0 8
  • 文/苍兰香墨 我抬头看了看天上的太阳。三九已至,却和暖如春,着一层夹袄步出监牢的瞬间,已是汗流浃背。 一阵脚步声响...
    开封第一讲书人阅读 26,444评论 0 180
  • 我被黑心中介骗来泰国打工, 没想到刚下飞机就差点儿被人妖公主榨干…… 1. 我叫王不留,地道东北人。 一个月前我还...
    沈念sama阅读 34,553评论 2 249
  • 正文 我出身青楼,却偏偏与公主长得像,于是被迫代替她去往敌国和亲。 传闻我的和亲对象是个残疾皇子,可洞房花烛夜当晚...
    茶点故事阅读 34,618评论 2 249

推荐阅读更多精彩内容