Gradle插件开发-上传apk文件到Bugly

96
IT_xiao小巫
0.1 2016.07.31 13:37* 字数 1680

前言

上一篇文章已经给大家详细介绍了如何通过Gradle将我们开发好的Library上传到JCenter,基本上就是一系列配置,最后通过Gradle脚本将Library打包成jar或者aar包上传到maven仓库,然后添加到JCenter仓库进行审核,通过之后就能让开发者在gradle脚本进行引用。本篇博客还是基于Gradle,但稍微进阶一下,将跟大家分享一下如何开发一个Gradle插件,这个插件是我为Bugly开发的自动上传apk文件的Gradle插件,目前已经开源,有兴趣的朋友可以到github看看:https://github.com/BuglyDevTeam/BuglyBetaUploader

什么是Gradle插件?

这个问题问得很好,我们来举个例子,在使用Android Studio进行开发的时候,我们创建一个Android工程,会默认生成一个build.gradle脚本,打开脚本你会看到以下代码:

apply plugin: 'com.android.application'

大家有没有想过为什么会有这么一句代码?如果我们创建一个Library的话,就会变成:

apply plugin: 'com.android.library'

其实这就是在gradle脚本引用android为我们提供的插件,plugin表示插件,'com.android.application’表示我们引用的插件名,通常是以包名来命名。

这里还有一个问题,这个插件是怎么被引用进来的?我们可以在根目录找到另外一个build.gradle文件,打开可以看到以下代码:

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.0.0'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        jcenter()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

稍微解释下,buildscript方法是定义了全局的相关属性,repositories定义了jcenter作为仓库。一个仓库代表着你的依赖包的来源,例如maven仓库。dependencies用来定义构建过程。classpath 'com.android.tools.build:gradle:2.0.0',就是将远程的插件下载到本地并将其构建到我们工程当中。

那怎么找到插件下载的路径呢,如下图所示 :

android插件

你可以看到我们在android studio所用到的所有插件和Library都会下载这个目录下,这下子你应该对gradle引用插件的原理有一定的理解了吧。

如何开发Gradle插件?

这个也是本篇博客要讲的内容,要理解这部分内容需要大家先去了解Groovy这个语言,因为我们开发Gradle插件使用的就是Groovy语言,可以看看在开源中国对这门语言的描述:

这里写图片描述

这部分内容同学们自己去研究,本篇博客不会过多的讲解它的语法,其实你完全可以将它作为Java来用,后面你可以看到我写的一些代码其实跟Java没有太大差别。

步骤1:创建groovy工程

在Android Studio不能直接创建groovy工程,但我们可以按照下面步骤来创建:

  1. 创建一个Android项目
  2. 新建一个module,选择Androd Library
  3. 删除除build.gradle之外的所有文件
  4. 按照Groovy工程模板创建对应的目录

最终创建出来的工程如下图所示:

betauploader

第4步:在新建的module中新建文件夹src,接着在src文件目录下新建main文件夹,在main目录下新建groovy目录,这时候groovy文件夹会被Android识别为groovy源码目录。除了在main目录下新建groovy目录外,你还要在main目录下新建resources目录,同理resources目录会被自动识别为资源文件夹。在groovy目录下新建项目包名,就像Java包名那样。resources目录下新建文件夹META-INF,META-INF文件夹下新建gradle-plugins文件夹

步骤2:配置gradle

apply plugin: 'groovy'
apply plugin: 'maven'

dependencies {
    compile gradleApi()
    compile localGroovy()
}

repositories {
    mavenCentral()
}
group = 'com.tencent.bugly.plugin'
version = '1.0.0'

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: uri('../repo'))
        }
    }
}

group将会表示插件的groupId,version表示插件的版本,这段代码会在gradle toolbar生成一个task,执行这个task会将插件发布到本地的repo目录下,这里注意下,我们正在开发阶段,不需要将gradle插件上传到maven,我们将它发布到自己指定的目录下即可。

uploadArchives

执行uploadArchives这个task,就会在repo目录下生成指定版本的插件:

gradle插件生成

步骤3:创建BetaPlugin

这里就不把完整的实现代码贴出来,只贴大体的框架:

public class BetaPlugin implements Plugin<Project> {
    ...
    
     @Override
    void apply(Project project) {
        ...
    }

    ...

}

创建一个Plugin就需要实现Plugin接口,并且重写它的apply方法,这个类当中就是用来实现插件的逻辑的,比如创建task,获取外部的参数都需要在这里面完成。

代码开发完毕之后,在resources/META-INF/gradle-plugins目录下新建一个properties文件,注意该文件的命名就是你使用插件的名字,这里命名为com.tencent.bugly.plugin.betauploader.properties,在里面输入:

implementation-class=com.tencent.bugly.plugin.BetaPlugin

这样就完成插件的配置了。

步骤4:接收外部参数

apply plugin: 'com.tencent.bugly.plugin.betauploader' // 应用上传apk插件

// beta配置
beta {
    appId = '900037672'
    appKey = 'bQvYLRrBNiqUctfi'
    title = "测试"
    desc = "beta apk uploader "
    enable = true
    autoUpload = false
    debugOn = false
}

基本上插件的使用就是这样,beta包含的配置都是用户设置让我们插件接收的外部参数,每个参数基本以key = value的形式设置。

要实现接收外部参数就需要自定义一个定义外部参数的类,如下所示:

package com.tencent.bugly.plugin

/**
 * Beta extension params
 * @author wenjiewu
 */
public class BetaExtension {
    public String appId = null // AppID 【必选】
    public String appKey = null // AppKey 【必选】
    //  【option】
    // 【接口参数】
    public String title = null // 标题
    public String desc = null // 版本描述
    public int secret = 1 // 公开范围(1:所有人,2:密码,4管理员,5QQ群,6白名单)
    public String users = null // 如果公开范围是"QQ群"填QQ群号;如果公开范围是"白名单"填QQ号码,并使用;切分开,5000个以内。其他场景无需设置
    public String password = null // 密码(如果公开范围是"密码"需设置)
    public int download_limit = 1000 // 下载上限(大于0,默认1000)
    public String expId = null // 需替换安装包的版本id

    // 【插件配置】
    public String apkFile = null // 指定上传的apk文件
    public Boolean enable = true // 插件开关
    public Boolean autoUpload = false // 是否自动上传
    public Boolean debugOn = false // debug模式是否上传
}

这些参数都是可以让用户配置的。

在插件里面,我们可以通过下面这种方式取得参数的值:

     // 接收外部参数
     project.extensions.create("beta", BetaExtension)
     def appId = project.beta.appId
     ...

步骤5: 创建Task

我们最终要实现的是通过task能够将apk文件上传到bugly平台,代码实现如下:

   /**
     * 创建上传任务
     *
     * @param variant 编译参数
     * @return
     */
    private Task createUploadTask(Object variant) {
        String variantName = variant.name.capitalize()
        Task uploadTask = project.tasks.create("upload${variantName}BetaApkFile") << {
            // if debug model and debugOn = false no execute upload
            if (variantName.contains("Debug") && !project.beta.debugOn) {
                println("Bugly: the option debugOn is closed, if you want to upload apk file on debug model, you can set debugOn = true to open it")
                return
            }
            uploadApk(generateUploadInfo(variant))
        }

        println("Bugly:create upload${variantName}BetaApkFile task")
        return uploadTask
    }

更加具体的代码细节,大家可以可以看我开源的代码。

发布到JCenter

插件开发完毕之后,就可以通过gradle脚本将开发好的代码打包上传到JCenter,基本上步骤跟上传Library是类似的,完整代码如下:

apply plugin: 'com.jfrog.bintray'
apply plugin: 'maven-publish'


group = "com.tencent.bugly.plugin"
version = "1.0.2"

def baseUrl = 'https://github.com/BuglyDevTeam'
def siteUrl = baseUrl
def gitUrl = "${baseUrl}/BuglyBetaUploder.git"
def issueUrl = "${baseUrl}/BuglyBetaUploder/issues"

def projectName = "betauploader"
def mavenDesc = 'bugly beta uploader'
def licenseIds = ['Apache-2.0']

install {
    repositories.mavenInstaller {
        // This generates POM.xml with proper parameters
        pom.project {
            // packaging 'jar'
            // Add your description here
            name = 'Upload apk file to bugly platform'
            url siteUrl
            // Set your license
            licenses {
                license {
                    name = 'The Apache Software License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                }
            }
            developers {
                developer {
                    id 'YOUR_ID'
                    name 'YOUR_NAME'
                    email 'YOUR_EMAIL'
                }
            }
            scm {
                connection gitUrl
                developerConnection gitUrl
                url siteUrl
            }
        }
    }
}

task sourcesJar(type: Jar) {
    from 'src/main/groovy'
    exclude 'META-INF'
    classifier = 'sources'
}

groovydoc {
    includePrivate = true
    source = 'src/main/groovy'
}

task groovydocJar(type: Jar, dependsOn: groovydoc) {
    classifier = 'javadoc'
    from groovydoc.destinationDir
}

artifacts {
    archives groovydocJar
    archives sourcesJar
}

Properties properties = new Properties()
properties.load(project.rootProject.file('local.properties').newDataInputStream())

bintray {
    user = properties.getProperty("bintray.user")
    key = properties.getProperty("bintray.apikey")

    configurations = ['archives']

    pkg {
        repo = 'maven'
        name = projectName
        desc = mavenDesc
        websiteUrl = siteUrl
        issueTrackerUrl = issueUrl
        vcsUrl = gitUrl
        labels = ['gradle', 'com.tencent.bugly.plugin', 'betauploader']
        licenses = licenseIds
        publish = true
        publicDownloadNumbers = true
    }
}

至此,插件就已经开发完毕啦,通过gradle bintrayUpload的命令将插件上传到bintray中的maven仓库,然后添加到JCenter仓库审核即可。

具体的使用方法,可以参考:https://bugly.qq.com/betaGradle

最后

关于Gradle插件的开发也告一段落啦,相对来说这个插件的功能还比较单一,更加复杂的插件开发可以参考其他开源的项目,只要多查多实践,相信开发一个你自己的插件并不是一件很难的事。

Gradle
Web note ad 1