OpenCV-图像处理-频域手段添加盲水印

[傅里叶变换算法及盲水印实现]
盲水印,顾名思义就是看不见的水印。今天我们来说下频域加盲水印。相信大家做过图像处理的对频域、时域、空间域概念都有了一定的了解。

空间域,我们日常所见的图像就是空域。空域添加数字水印的方法是在空间域直接对图像操作(之所以说的这么绕,是因为不仅仅原图是空域,原图的差分等等也是空域),比如将水印直接叠加在图像上。
频域:描述信号在频率方面特性时用到的一种坐标系。在图像中就是图像灰度变化强烈的情况,图像的频率。
时域:是描述数学函数或物理信号对时间的关系。例如一个信号的时域波形可以表达信号随着时间的变化。

下边来说说频域添加盲水印原理:频域添加数字水印的方法,是指通过某种变换手段(傅里叶变换,离散余弦变换,小波变换等)将图像变换到频域(小波域),在频域对图像添加水印,再通过逆变换,将图像转换为空间域。相对于空域手段,频域手段隐匿性更强,抗攻击性更高。
如果对频域、傅里叶转换不太懂得,可以参考这篇文章如果看了此文你还不懂傅里叶变换,那就过来掐死我吧【完整版】,感谢大神。

傅里叶变换公式png

我们有方法将时域信号转换成为频域,同样,我们也能将二维信号(图像)转换为频域。
因为图像是离散信号,我们实际用的是离散傅里叶变换,在本文采用的都是二维快速傅里叶变换,快速傅里叶变换与离散傅里叶变换等价。

添加盲水印流程:

傅里叶转换添加水印.png

水印提取是水印叠加的逆过程:

水印提取.png

上边说了下一些基础及频域加盲水印原理。下边来说下具体代码,具体代码用iOS来实现,我们使用OpenCV3来实现,OpenCV3对图像处理使用 Mat(包含信息有矩阵的大小,用于存储的方法,矩阵存储的地址等)的矩阵头和一个指针指向包含了像素值的矩阵。而OpenCV2是IplImage,如果你在查找资料的时候发现IplImage则是之前的C实现的。因为我们使用OpenCV3是C++实现的只要看懂学会,Android、python等都可以按照其代码来实现的。
首先我们先来建个工程来添加OpenCV库,我们这里是pod下来的库----pod 'OpenCV', '~> 3.2.0',方便管理。

全局先定义:
   cv::Mat _complexImage;
   vector<Mat> planes;
   vector<Mat> allPlanes;
1.原始图片UIImage转Mat进行处理
- (cv::Mat)cvMatFromUIImage:(UIImage *)image
{
    UIImage *tmpImage = image;
    CGColorSpaceRef colorSpace = CGImageGetColorSpace(tmpImage.CGImage);
    CGFloat cols = tmpImage.size.width;
    CGFloat rows = tmpImage.size.height;
    
    cv::Mat cvMat(rows, cols, CV_8UC4);
    CGContextRef contextRef = CGBitmapContextCreate(cvMat.data,cols,rows,8,cvMat.step[0],colorSpace,kCGImageAlphaNoneSkipLast | kCGBitmapByteOrderDefault);
    CGContextDrawImage(contextRef, CGRectMake(0, 0, cols, rows), tmpImage.CGImage);
    CGContextRelease(contextRef);
 return cvMat;
}
2.为了加快傅里叶转换速度,先对图片进行尺寸优化
- (cv::Mat)optimizeImageDim:(cv::Mat)image  {
    Mat padded =  Mat();
    // get the optimal rows size for dft
    int addPixelRows = getOptimalDFTSize(image.rows);
    // get the optimal cols size for dft
    int addPixelCols = getOptimalDFTSize(image.cols);
    // apply the optimal cols and rows size to the image
    copyMakeBorder(image, padded, 0, addPixelRows - image.rows, 0, addPixelCols - image.cols, BORDER_CONSTANT, Scalar::all(0));
    return padded;
}
3.由于只能在单通道处理,所以要分离图片多通道
//分离多通道获取B通道  
- (cv::Mat)splitSrc:(cv::Mat) image {
    //清空allPlanes
    if (!allPlanes.empty()) {
        allPlanes.clear();
    }
    //分离image通道到allPlanes
    //先优化
    Mat optimizeImage = [self optimizeImageDim:image];
    split(optimizeImage,allPlanes);
    Mat padded =  Mat();
    if (allPlanes.size()>1) {
        for (int i = 0; i < allPlanes.size();i++) {
            if (i == 0) {
                // optimize the dimension of the loaded image
                //分离之前优化,这里不需要优化
                  padded = allPlanes[i];
//                padded = [self optimizeImageDim:allPlanes[i]];
                break;
            }
        }
    } else {
        padded = [self optimizeImageDim:image];
    }
    return padded;
}
4.对图片进行傅里叶转换并在频谱上添加文本
- (void)transformImageWithText:(cv::Mat) image blindMarkText:(NSString *) blindMarkText point:(cv::Point) point fontSize:(double)fontSize scalar:(cv::Scalar) scalar {
    // planes数组中存的通道数若开始不为空,需清空.
    if (!planes.empty()) {
        planes.clear();
    }
    Mat padded = [self splitSrc:image];
     padded.convertTo(padded, CV_32F);
    // prepare the image planes to obtain the complex image
    planes.push_back(padded);
    planes.push_back(cv::Mat::zeros(padded.size(), CV_32F));
    // prepare a complex image for performing the dft
    merge(planes, _complexImage);
    // dft
    dft(_complexImage, _complexImage);
    // 频谱图上添加文本
    putText(_complexImage, [blindMarkText UTF8String], point, CV_FONT_HERSHEY_DUPLEX, fontSize, scalar);
    flip(_complexImage, _complexImage, -1);
    putText(_complexImage, [blindMarkText UTF8String], point, CV_FONT_HERSHEY_DUPLEX, fontSize, scalar);
    flip(_complexImage, _complexImage, -1);
    planes.clear();
}
5.idft把处理过后的图片恢复成原图
- (cv::Mat)antitransformImage {
    Mat invDFT ;
    idft(_complexImage, invDFT, DFT_SCALE | DFT_REAL_OUTPUT, 0);
    Mat restoredImage ;
    invDFT.convertTo(restoredImage, CV_8U);
    //合并多通道
    allPlanes.erase(allPlanes.begin());
    allPlanes.insert(allPlanes.begin(), restoredImage);
    Mat lastImage ;
    merge(allPlanes,lastImage);

    return lastImage;
}
6.Mat转UIImage
- (UIImage *)UIImageFromCVMat:(cv::Mat)cvMat
{
    NSData *data = [NSData dataWithBytes:cvMat.data length:cvMat.elemSize()*cvMat.total()];
    CGColorSpaceRef colorSpace;
    
    if (cvMat.elemSize() == 1) {
        colorSpace = CGColorSpaceCreateDeviceGray();
    } else {
        colorSpace = CGColorSpaceCreateDeviceRGB();
    }
    
    CGDataProviderRef provider = CGDataProviderCreateWithCFData((__bridge CFDataRef)data);
    
    CGImageRef imageRef = CGImageCreate(cvMat.cols,                             cvMat.rows,8, 8 * cvMat.elemSize(), cvMat.step[0],colorSpace, kCGImageAlphaNone|kCGBitmapByteOrderDefault, provider, NULL, false,kCGRenderingIntentDefault);
    UIImage *finalImage = [UIImage imageWithCGImage:imageRef];
    CGImageRelease(imageRef);
    CGDataProviderRelease(provider);
    CGColorSpaceRelease(colorSpace);
    
    return finalImage;
}
到这里我们盲水印所需要的函数、方法已经写完,具体调用
- (void)fourierConversion {
cv::Mat orignMat = [self cvMatFromUIImage:[UIImage imageNamed:imageName]];
 cv::Scalar color = CV_RGB(0,255,255);
    [self transformImageWithText:orignMat blindMarkText:@"Test" point:cv::Point(45,45) fontSize:0.8 scalar:color];
    cv::Mat cvMat = [self antitransformImage];
    self.imgView.image = [self UIImageFromCVMat:cvMat];
}
图片.jpg

这时候你会发现图片和原来没什么区别。是的,确实肉眼看没有任何区别.

下边我们获取到水印:
1.创建优化级
- (cv::Mat)createOptimizedMagnitude:(cv::Mat)complexImage {
    // init
    vector<Mat> newPlanes = {};
    Mat mag =  Mat();
    // split the comples image in two planes
    split(complexImage, newPlanes);
    // compute the magnitude
    magnitude(newPlanes[0], newPlanes[1], mag);
    // move to a logarithmic scale
    add(Mat::ones(mag.size(), CV_32F), mag, mag);
    // optionally reorder the 4 quadrants of the magnitude image
    [self shiftDFT:mag];
    // normalize the magnitude image for the visualization 
    // and OpenCV need images with value between 0 and 255
    // convert back to CV_8UC1
    mag.convertTo(mag, CV_8UC1);
    normalize(mag, mag, 0, 255, NORM_MINMAX, CV_8UC1);
    return mag;
}
2.转化DFT
- (void)shiftDFT:(cv::Mat)image {
    
    image = image(cv::Rect(0, 0, image.cols & (-2), image.rows & (-2)));
    
    int cx = image.cols / 2;
    int cy = image.rows / 2;
    
    Mat q0 = Mat(image, cv::Rect(0, 0, cx, cy));
    Mat q1 = Mat(image,  cv::Rect(cx, 0, cx, cy));
    Mat q2 =  Mat(image,  cv::Rect(0, cy, cx, cy));
    Mat q3 =  Mat(image,  cv::Rect(cx, cy, cx, cy));
    
    Mat tmp =  Mat();
    q0.copyTo(tmp);
    q3.copyTo(q0);
    tmp.copyTo(q3);
    
    q1.copyTo(tmp);
    q2.copyTo(q1);
    tmp.copyTo(q2);
}
3.转换图片获取水印图
- (cv::Mat)transformImage:(cv::Mat)image {
    // planes数组中存的通道数若开始不为空,需清空.
    if (!planes.empty()) {
        planes.clear();
    }
     Mat padded = [self splitSrc:image];
    padded.convertTo(padded, CV_32F);
    // prepare the image planes to obtain the complex image
    planes.push_back(padded);
    planes.push_back(cv::Mat::zeros(padded.size(), CV_32F));
    // prepare a complex image for performing the dft
    merge(planes, _complexImage);
    // dft
    dft(_complexImage, _complexImage);
    // optimize the image resulting from the dft operation
    Mat magnitude = [self createOptimizedMagnitude:_complexImage];
    planes.clear();
    return magnitude;
}
获取水印具体调用:
- (void)reverseFourier {
    cv::Mat cvMat = [self antitransformImage];
    cvMat = [self transformImage:cvMat];
    self.imgView.image = [self UIImageFromCVMat:cvMat];
}
盲水印.png
引用下别人的语言:

频域添加数字水印的方法,是指通过某种变换手段(傅里叶变换,离散余弦变换,小波变换等)将图像变换到频域(小波域),在频域对图像添加水印,再通过逆变换,将图像转换为空间域。相对于空域手段,频域手段隐匿性更强,抗攻击性更高。所谓对水印的攻击,是指破坏水印,包括涂抹,剪切,放缩,旋转,压缩,加噪,滤波等。数字盲水印不仅仅要敏捷性高(不被人抓到),也要防御性强(抗打)。就像Dota的敏捷英雄往往是脆皮,数字盲水印的隐匿性和鲁棒性是互斥的。(鲁棒性是抗攻击性的学术名字)。

有许多同学还是不懂,我把核心代码封成了库,需要的请自己去clone。
封装库地址:https://github.com/miaozhang9/opencvLib.git

最后编辑于
©著作权归作者所有,转载或内容合作请联系作者
  • 序言:七十年代末,一起剥皮案震惊了整个滨河市,随后出现的几起案子,更是在滨河造成了极大的恐慌,老刑警刘岩,带你破解...
    沈念sama阅读 148,827评论 1 317
  • 序言:滨河连续发生了三起死亡事件,死亡现场离奇诡异,居然都是意外死亡,警方通过查阅死者的电脑和手机,发现死者居然都...
    沈念sama阅读 63,511评论 1 266
  • 文/潘晓璐 我一进店门,熙熙楼的掌柜王于贵愁眉苦脸地迎上来,“玉大人,你说我怎么就摊上这事。” “怎么了?”我有些...
    开封第一讲书人阅读 99,318评论 0 218
  • 文/不坏的土叔 我叫张陵,是天一观的道长。 经常有香客问我,道长,这世上最难降的妖魔是什么? 我笑而不...
    开封第一讲书人阅读 42,108评论 0 189
  • 正文 为了忘掉前任,我火速办了婚礼,结果婚礼上,老公的妹妹穿的比我还像新娘。我一直安慰自己,他们只是感情好,可当我...
    茶点故事阅读 50,112评论 1 266
  • 文/花漫 我一把揭开白布。 她就那样静静地躺着,像睡着了一般。 火红的嫁衣衬着肌肤如雪。 梳的纹丝不乱的头发上,一...
    开封第一讲书人阅读 39,387评论 1 185
  • 那天,我揣着相机与录音,去河边找鬼。 笑死,一个胖子当着我的面吹牛,可吹牛的内容都是我干的。 我是一名探鬼主播,决...
    沈念sama阅读 30,905评论 2 283
  • 文/苍兰香墨 我猛地睁开眼,长吁一口气:“原来是场噩梦啊……” “哼!你这毒妇竟也来了?” 一声冷哼从身侧响起,我...
    开封第一讲书人阅读 29,657评论 0 177
  • 序言:老挝万荣一对情侣失踪,失踪者是张志新(化名)和其女友刘颖,没想到半个月后,有当地人在树林里发现了一具尸体,经...
    沈念sama阅读 33,144评论 0 223
  • 正文 独居荒郊野岭守林人离奇死亡,尸身上长有42处带血的脓包…… 初始之章·张勋 以下内容为张勋视角 年9月15日...
    茶点故事阅读 29,744评论 2 225
  • 正文 我和宋清朗相恋三年,在试婚纱的时候发现自己被绿了。 大学时的朋友给我发了我未婚夫和他白月光在一起吃饭的照片。...
    茶点故事阅读 31,100评论 1 236
  • 序言:一个原本活蹦乱跳的男人离奇死亡,死状恐怖,灵堂内的尸体忽然破棺而出,到底是诈尸还是另有隐情,我是刑警宁泽,带...
    沈念sama阅读 27,565评论 2 222
  • 正文 年R本政府宣布,位于F岛的核电站,受9级特大地震影响,放射性物质发生泄漏。R本人自食恶果不足惜,却给世界环境...
    茶点故事阅读 32,041评论 3 216
  • 文/蒙蒙 一、第九天 我趴在偏房一处隐蔽的房顶上张望。 院中可真热闹,春花似锦、人声如沸。这庄子的主人今日做“春日...
    开封第一讲书人阅读 25,769评论 0 9
  • 文/苍兰香墨 我抬头看了看天上的太阳。三九已至,却和暖如春,着一层夹袄步出监牢的瞬间,已是汗流浃背。 一阵脚步声响...
    开封第一讲书人阅读 26,301评论 0 178
  • 我被黑心中介骗来泰国打工, 没想到刚下飞机就差点儿被人妖公主榨干…… 1. 我叫王不留,地道东北人。 一个月前我还...
    沈念sama阅读 34,173评论 2 239
  • 正文 我出身青楼,却偏偏与公主长得像,于是被迫代替她去往敌国和亲。 传闻我的和亲对象是个残疾皇子,可洞房花烛夜当晚...
    茶点故事阅读 34,313评论 2 242

推荐阅读更多精彩内容