AWK

awk介绍

  • awk :Aho, Weinberger, Kernighan,报告生成器,格式化文本输出
  • 有多种版本:New awk(nawk),GNU awk(gawk)
  • gawk :模式扫描和处理语言
  • 基本用法:
awk [options] ‘program’ var=value file…
awk [options] -f programfile var=value file…
awk [options] 'BEGIN{ action;… } pattern{ action;… } END{ action;… }' file ...
awk  程序通常由:BEGIN 语句 块、能够使用模式匹配的通用语句块END语句块,共3部分组成
    program通常是被单引号或双引号中
选项:
    -F:指明输入时用到的字段分隔符
    -v var=value:自定义变量

awk语言

  • 基本格式:awk [options] 'program' file…
  • program:pattern{action statements;..}
  • pattern 和action: :
pattern 部分决定动作语句何时触发及触发事件
    BEGIN,END
action statements 对数据进行处理,放在{} 内指明
    print, printf
  • 分割符、域和记录
awk执行时,由分隔符分隔的字段(域)标记$1,$2..$n称为域标识。$0 为所有域,注意:和shell 中变量$ 符含义不同
文件的每一行称为记录
省略action行,则默认执行print $0 的操作
  • awk工作原理
第一步:执行BEGIN{action;… } 语句块中的语句
第二步:从文件或标准输入(stdin) 读取一行,然后执行pattern{ action;… } 语句块,它逐行扫描文件,从第一行到最后一行重复这个过程,直到文件全部被读取完毕。
第三步:当读至输入流末尾时,执 END{action;…} 语句块
    
    BEGIN语句块在awk 开始从输入流中读取行之前被执行,这是一个可选的语句块,比如变量初始化、打印输出表格的表头等语句通常可以写在BEGIN 语句块中
    END语句块在awk 从输入流中读取完所有的行之后即被执行,比如打印所有行的分析结果这类信息汇总都是在END 语句块中完成,它也是一个可选语句块
    pattern语句块中的通用命令是最重要的部分,也是可选的。如果没有提供pattern语句块,则默认执行{ print },即打印每一个读取到的行,awk读取的每一行都会执行该语句块

awk

print 格式:print item1, item2, ...
要点:
    (1)逗号分隔符
    (2)输出的各item可以字符串,也可以是数值;当前记录的字段、变量或awk的表达式
    (3)如省略item ,相当于print $0
示例:
    awk '{print "hello,awk"}'
    awk –F: '{print}' /etc/passwd
    awk –F: ‘{print “wang”}’ /etc/passwd
    awk –F: ‘{print $1}’ /etc/passwd
    awk –F: ‘{print $0}’ /etc/passwd
    awk –F: ‘{print $1”\t”$3}’ /etc/passwd
    tail –3 /etc/fstab |awk ‘{print $2,$4}’

awk变量

  • 变量:内置和自定义变量
模式 例子 匹配
BEGIN BEGIN 输入被读取之前
END END 所有输入被读取之后
expression $3>100 第三个字段大于100
string-matching /Asia/ 含有Asia的行
compound $3<100 && $4 =="Asia" 第三个字段小于100且第四个字段含有Asia的行
range NR == 10,NR==20 输入的第10行到20行
变量 意义 默认值
FS 控制这输入行的字段分隔符 " "
OFS 输出字段分隔符 " "
RS 控制着输入行的记录分隔符 "\n"
ORS 输出记录的分隔符 "\n"
NF 当前记录的字段个数 -
NR 到目前为止读的记录数量 -
FNR 当前输入文件的记录个数 -
ARGC 命令行参数的个数 -
ARGV 命令行参数数组 -
FILENAME 当前输入文件名 -
OFMT 数值的输出格式 "%.6g"
RLENGTE 被函数match匹配的字符串的长度 -
RSTART 被函数match匹配的字符串的开始
SUBSEP 下标分隔符 "\034"
FS:输入字段分隔符,默认为空白字符  
    awk -v FS=':' '{print $1,FS,$3}’ /etc/passwd
    awk –F: '{print $1,$3,$7}’ /etc/passwd
    s=:;awk -v FS=$s '{print $1 FS $3}' /etc/passwd
OFS:输出字段分隔符,默认为空白字符
    awk -v FS=‘:’ -v OFS=‘:’ '{print $1,$3,$7}’ /etc/passwd
RS:输入记录分隔符,指定输入时的换行符,原换行符仍有效
    awk -v RS=' ' ‘{print }’ /etc/passwd
ORS:输出记录分隔符,输出时用指定符号代替换行符
    awk -v RS=' ' -v ORS='###'‘{print }’ /etc/passwd
NF:字段数量
    awk -F:‘{print NF}’ /etc/fstab, 引用内置变量不用$
    awk -F: '{print $(NF-1)}' /etc/passwd
NR:行号
    awk '{print NR}' /etc/fstab ; awk END'{print NR}' /etc/fstab
FNR:各文件分别计数, 行号
    awk '{print FNR}' /etc/fstab /etc/inittab
FILENAME:当前文件名
    awk '{print FILENAME}’ /etc/fstab
ARGC:命令行参数的个数
    awk '{print ARGC}’ /etc/fstab /etc/inittab
    awk ‘BEGIN {print ARGC}’ /etc/fstab /etc/inittab
ARGV:数组,保存的是命令行所给定的各参数
    awk ‘BEGIN {print ARGV[0]}’ /etc/fstab /etc/inittab
    awk ‘BEGIN {print ARGV[1]}’ /etc/fstab /etc/inittab

自定义变量(区分字符大小写)
    (1) -v var=value
    (2) 在program中直接定义
示例:
    awk -v test='hello gawk' '{print test}' /etc/fstab
    awk -v test='hello gawk' 'BEGIN{print test}'
    awk 'BEGIN{test="hello,gawk";print test}'
    awk –F:‘{sex=“male”;print $1,sex,age;age=18}’ /etc/passwd
    cat awkscript 
    {print script,$1,$2}
    awk -F: -f awkscript script=“awk” /etc/passwd

printf命令

  • 格式化输出:printf “FORMAT ”, item1, item2, ...
(1)必须指定FORMAT
(2)不会自动换行,需要显式给出换行控制符,\n
(3)FORMAT中需要分别为后面每个item指定格式符
  • 格式符:与item一一对应
格式符 意义
%c 显示字符的ASCII码
%d,%i 显示十进制整数
%e,%E 显示科学计数法数值
%f 显示为浮点数
%g,%G 以科学计数法或浮点形式显示数值
%s 显示字符串
%u 无符号整数
%% 显示%自身
  • 修饰符:
#[.#] :第一个数字控制显示的宽度;第二个#表示小数点后精度,%3.1f
-: 左对齐(默认右对齐) %-15s
+:显示数值的正负符号 %+d
  • printf示例
awk -F: ‘{printf "%s",$1}’ /etc/passwd
awk -F: ‘{printf "%s\n",$1}’ /etc/passwd
awk -F: '{printf "%-20s %10d\n",$1,$3}' /etc/passwd
awk -F: ‘{printf "Username: %s\n",$1}’ /etc/passwd
awk -F: ‘{printf “Username: %s,UID:%d\n",$1,$3}’ /etc/passwd
awk -F: ‘{printf "Username: %15s,UID:%d\n",$1,$3}’ /etc/passwd
awk -F: ‘{printf "Username: %-15s,UID:%d\n",$1,$3}’ /etc/passwd

操作符表达式

  1. 初等表达式包括
    数值与字符串常量, 变量, 字段, 函数调用, 数组元素.
  2. 可以把表达式组合起来的运算符包括
赋值运算符 = += -= *= /= %= ^= 条件表达式 ?:    
逻辑运算符 || (OR), && (AND), ! (NOT)    
匹配运算符 ~ 和 !~    
关系运算符 < <= == != > >=    
拼接运算符 (没有显式的拼接运算符)   
算术运算符 + - * / % ^    
单目运算符 +和-    
自增与自减运算符 ++ 和 -- (包括前缀与后缀)    
括号 (用于分组)   
操作 运算符 例子 例子的含义
赋值 = += -= *= /= %= ^= x *= 2 x = x * 2
条件表达式 ?: x ? y : z 若 x 为真, 则 y, 否则 z
逻辑与 && x && y 若 x 与 y 都为真, 则为 1, 否则为 0
数组成员 in i in a 如果 a[i] 存在, 则为 1, 否则为 0
匹配 ~ !~ $1 ~ /x/ 如果第一个字段包含 x, 则为 1, 否则为 0
关系运算 < <= == != >= > x == y 如果 x 等于 y, 则为 1, 否则为 0
拼接 "a" "bc" "abc"; 不存在显式的拼接运算符
减法, 加法 + - x + y x 与 y 的和
乘法, 除法, 取模 * / % x % y x 除以 y 的余数
单目加, 单目减 + - -x x 的相反数
逻辑非 ! !$1 若 $1 为空或为 0, 则为 1, 否则为 0
指数运算 ^ x ^ y x的y次方
自增, 自减 ++ -- ++x, x++ 为 x 加 1
字段 $ $i+1 1 加上第 i 个字段的值
( ) ($i)++ 给第 i 个字段的值加 1
  • 算术操作符:
x+y, x-y, x*y, x/y, x^y, x%y
-x:转换为负数
+x:转换为数值
  • 字符串操作符:没有符号的操作符,字符串连接
  • 赋值操作符:
=, +=, -=, *=, /=, %=, ^=
++, --
  • 比较操作符:
==, !=, >, >=, <, <=
  • 模式匹配符
~:左边是否和右边匹配包含 
!~ :是否不匹配

示例:
    awk –F: '$0 ~ /root/{print $1}‘ /etc/passwd
    awk '$0~“^root"' /etc/passwd
    awk '$0 !~ /root/‘ /etc/passwd
    awk –F: ‘$3==0’ /etc/passwd
  • 逻辑操作符:
&& 与 
|| 或
! 非
  • 示例:
awk –F: '$3>=0 && $3<=1000 {print $1}' /etc/passwd
awk -F: '$3==0 || $3>=1000 {print $1}' /etc/passwd
awk -F: ‘!($3==0) {print $1}' /etc/passwd
awk -F: ‘!($3>=500) {print $3}’ /etc/passwd
awk -F: '$3 > 100 && $3<1000 {print $1,$3}' passwd
  • 函数调用: function_name(argu1, argu2, ...)
  • 条件表达式(三目表达式):
selector?if-true-expression:if-false-expression

示例:
    awk -F: '{$3>=1000?usertype="Common User":usertype="Sysadmin or SysUser";printf "%15s:%-s\n",$1,usertype}' /etc/passwd
    awk -F: '{$3>1000?username="common user:":username="sysuser:";printf "%s %-30s %d\n",username,$1,$3}' passwd

正则表达式

  1. 正则表达式的元字符包括:
\ ^ $ . [] | ()  * + ?
  1. 一个基本的正则表达式包括以下几种:
一个不是元字符的字符,例如A,这个正则表达式匹配的就是它本身;
一个匹配特殊字符的转义字符:\t匹配一个制表符
一个被引用的元字符,例如\*,按字面意义匹配元字符
^ 匹配一行的开始
$ 匹配一行的结束
. 匹配任意一个字符
一个字符类:[ABC]匹配字符A、B或C
字符类可能包能包含缩写格式:[A-Za-z]匹配单个字母
一个互补的字符类:[^0-9] 匹配任意一个字符,但除了数字
  1. 运算符组合起来使用
选择:A|B 匹配A或B
拼接:AB匹配后面紧跟着B的A
闭包:A*匹配0个或多个A
正必包:A+匹配一个或多个A
零或一:A?匹配空字符串或A
括号:被(r)匹配的字符串,与r所匹配的字符串相同
  1. 优先级
选择运算符 | 优先级最低,然后是拼接运算,最后是重复运算+,*与?;
  1. 转义序列
序列 意义
\b 退格
\f 换页
\n 换行
\r 回车
t 制表符
\ddd 八进制数ddd.ddd含有1到3个数字,每个数字的值在0-7之间
\c 其他字面意义上的c(如\表示,"表示双引号)
  • 示例
^[^^] 匹配不以脱字符开始的字符串
/^[0-9]+$/ 匹配含有且只含有数字的输入行
/^[0-9][0-9][0-9]$/ 输入行有且仅有 3 个数字.
/^(\+|-)?[0-9]+\.?[0-9]*$/ 十进制小数, 符号与小数部分是可选的.
/^[+-]?[0-9]+[.]?[0-9]*$/ 也是匹配十进制小数, 带有可选的符号与小数部分.
/^[+-]?([0-9]+[.]?[0-9]*|[.][0-9]+)([eE][+-]?[0-9]+)?$/ 浮点数, 符号与指数部分是可选的.
/^[A-Za-z][A-Za-z0-9]*$/ 一个字母, 后面再跟着任意多个字母或数字 (比如awk的变量名).
/^[A-Za-z]$|^[A-Za-z][0-9]$/ 一个字母, 又或者是一个后面跟着一个数字的字母 (比如 Basic 的变量名).
/^[A-Za-z][0-9]?$/ 同样是一个字母, 又或者是一个后面跟着一个数字的字母

awk PATTERN

  • PATTERN: 根据pattern 条件,过滤匹配的行,再做处理
(1) 如果未指定:空模式,匹配每一行
(2) /regular expression/ :仅处理能够模式匹配到的行,需要用/ / 括起来
    awk '/^UUID/{print $1}' /etc/fstab
    awk '!/^UUID/{print $1}' /etc/fstab
(3) relational expression:  关系表达式,结果为“真”才会被处理
    真:结果为非0 值,非空字符串
    假:结果为空字符串或0值 值

    示例:
        awk -F: 'i=1;j=1{print i,j}' /etc/passwd
        awk ‘!0’ /etc/passwd ; awk ‘!1’ /etc/passwd
        awk –F: '$3>=1000{print $1,$3}' /etc/passwd
        awk -F: '$3<1000{print $1,$3}' /etc/passwd
        awk -F: '$NF=="/bin/bash"{print $1,$NF}' /etc/passwd
        awk -F: '$NF ~ /bash$/{print $1,$NF}' /etc/passwd
(4) line ranges:行范围
    startline,endline
    /pat1/,/pat2/  
    
    awk -F: ‘/^root\>/,/^nobody\>/{print $1}' /etc/passwd
    
    注意:不支持直接给出数字格式
    awk -F: ‘(NR>=10&&NR<=20){print NR,$1}' /etc/passwd
(5) BEGIN/END 模式
    BEGIN{}: 仅在开始处理文件中的文本之前执行一次
    END{} :仅在文本处理完成之后执行一次
    
示例
    awk -F : 'BEGIN {print "USER USERID"} {print $1":"$3} END{print "end file"}' /etc/passwd
    awk -F : '{print "USER USERID“;print $1":"$3} END{print "end file"}' /etc/passwd
    awk -F: 'BEGIN{print " USER UID \n--------------- "}{print $1,$3}' /etc/passwd
    awk -F: 'BEGIN{print " USER UID \n--------------- "}{print $1,$3}'END{print "=============="} /etc/passwd 
    seq 10 |awk ‘i=0’
    seq 10 |awk ‘i=1’
    seq 10 | awk 'i=!i‘
    seq 10 | awk '{i=!i;print i}‘
    seq 10 | awk ‘!(i=!i)’
    seq 10 |awk -v i=1 'i=!i'

模式总结

模式|例子|匹配
-- | --| --
BEGIN|BEGIN|输入被读取之前
END|END|所有输入被读取之后
expression|$3>100|第三个字段大于100
string-matching|/Asia/|含有Asia的行
compound|$3<100 && $4 =="Asia"|第三个字段小于100且第四个字段含有Asia的行
range|NR == 10,NR==20|输入的第10行到20行

awk action

  • 常用的action 分类
(1) Expressions: 算术,比较表达式等
(2) Control statements:if,while等
(3) Compound statements:组合语句
(4) input statements
(5) output statements :print等

awk 控制语句

{ statements;… }  组合语句
if(condition) {statements;…}
if(condition) {statements;…} else {statements;…}
while(conditon) {statments;…}
do {statements;…} while(condition)
for(expr1;expr2;expr3) {statements;…}
break
continue
next 开始输入主循环的下一次迭代
delete array[index]
delete array
exit
exit expression 马上执行END 动作; 如果已经在END动作内, 那就退出程序. 将 expression 作为程序的退出状态返回.

awk控制语句

if-else

语法:
    if(condition){statement;…}[else statement]
    if(condition1){statement1}else if(condition2){statement2}
        else{statement3}
使用场景:对awk取得的整行或某个字段做条件判断
示例:
    awk -F: '{if($3>=1000)print $1,$3}' /etc/passwd
    awk -F: '{if($NF=="/bin/bash") print $1}' /etc/passwd
    awk '{if(NF>5) print $0}' /etc/fstab
    awk -F: '{if($3>=1000) {printf "Common user: %s\n",$1} else {printf "root or Sysuser: %s\n",$1}}' /etc/passwd
    awk -F: '{if($3>=1000) printf "Common user: %s\n",$1;
        else printf "root or Sysuser: %s\n",$1}' /etc/passwd
    df -h|awk -F% '/^\/dev/{print $1}'|awk '$NF>=80{print $1,$5}‘
    awk 'BEGIN{ test=100;if(test>90){print "very good"}
        else if(test>60){ print "good"}else{print "no pass"}}'

awk控制语句

  • while循环
语法:
    while(condition){statement;…}
条件“真”,进入循环;条件“假”, 退出循环
使用场景:
    对一行内的多个字段逐一类似处理时使用
    对数组中的各元素逐一处理时使用
示例:
    awk '/^[[:space:]]*linux16/{i=1;while(i<=NF) {print $i,length($i); i++}}' /etc/grub2.cfg
  • do-while循环
语法:
    do {statement;…}while(condition)
    意义:无论真假,至少执行一次循环体
示例:
    awk 'BEGIN{ total=0;i=0;do{ total+=i;i++;}while(i<=100);print total}‘
思考:下面两语句有何不同?
    awk ‘BEGIN{i=0;print ++i,i}’
    awk ‘BEGIN{i=0;print i++,i}’
  • for循环
语法:
    for(expr1;expr2;expr3) {statement;…}
常见用法:
    for(variable assignment;condition;iteration process) 
        {for-body}
特殊用法:能够遍历数组中的元素
    语法:for(var in array) {for-body}
示例:
    awk '/^[[:space:]]*linux16/{for(i=1;i<=NF;i++) {print $i,length($i)}}' /etc/grub2.cfg
  • 空语句
    单独一个分号表示一个空语句
在下面这个程序里, for 的循环体是一个空语句.
    BEGIN { FS = "\t" }
        { for (i = 1; i <= NF && $i != ""; i++)
            ;
            if (i <= NF)
                print
        }
这个程序打印所有的, 包含空字段的行.

性能比较

  • time (awk 'BEGIN{
    total=0;for(i=0;i<=10000;i++){total+=i;};print total;}')
  • time(total=0;for i in {1..10000};do
    total=$(($total+i));done;echo $total)
  • time(for ((i=0;i<=10000;i++));do let total+=i;done;echo
    $total)
  • time(seq –s ”+” 10000|bc)

awk控制语句

  • switch语句
语法:
    switch(expression) {case VALUE1 or /REGEXP/: statement1; case VALUE2 or /REGEXP2/: statement2; ...; default: statementn}
  • break 和continue
awk ‘BEGIN{sum=0;for(i=1;i<=100;i++)
    {if(i%2==0)continue;sum+=i}print sum}‘
awk ‘BEGIN{sum=0;for(i=1;i<=100;i++)
    {if(i==66)break;sum+=i}print sum}‘
  • break [n]
  • continue [n]
  • next:
    提前结束对本行处理而直接进入下一行处理(awk自身循环)
    awk -F: '{if($3%2!=0) next; print $1,$3}' /etc/passwd

awk 数组

  • 关联数组:array[index-expression]
index-expression:
    (1)可使用任意字符串;字符串要使用双引号括起来
    (2)如果某数组元素事先不存在,在引用时,awk会自动创建此元素,并将其值初始化为“空串”
    若要判断数组中是否存在某元素,要使用“index in array”格式进行遍历

示例:
    weekdays[“mon”]="Monday“
    awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="Tuesday";print weekdays["mon"]}''
    awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="tuesday";for(i in weekdays) print weekdays[i]}'    
    awk ‘!arr[$0]++’ dupfile   重复的行只显示一次
    awk '{!arr[$0]++;print $0, arr[$0]}' dupfile   
  • 若要遍历数组中的每个元素,要使用for循环
for(var in array) {for-body}
注意:var会遍历array的每个索引
示例:
    awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"] ="Tuesday";for(i in weekdays) {print weekdays[i]}}‘
    
    netstat -tan | awk '/^tcp/{state[$NF]++}END {for(i in state) { print i,state[i]}}'
    
    awk '{ip[$1]++}END{for(i in ip) {print i,ip[i]}}' /var/log/httpd/access_log

awk函数

  • 数值处理:
rand():返回0和1之间一个随机数
    awk 'BEGIN{srand(); for (i=1;i<=10;i++)print int(rand()*100) }'

内建算术函数

函数 返回值
atan2(y,x) y/x的反正切值, 定义域在 −π 到π之间
cos(x) x的余弦值, x以弧度为单位
exp(x) x的指数函数,e x
int(x) x的整数部分; 当x大于0时, 向 0取整
log(x) x的自然对数(以e为底)
rand() 返回一个随机数r, 0 ≤ r < 1
sin(x) x的正弦值, x以弧度为单位.
sqrt(x) x的方根
srand(x) x是rand() 的新的随机数种子
  • 字符串处理:
length([s]):返回指定字符串的长度
sub(r,s,[t]):对t字符串进行搜索r 表示的模式匹配的内容,并将第一个匹配的内容替换为s
    echo "2008:08:08 08:08:08" | awk 'sub(/:/,“-",$1)'
gsub(r,s,[t]):对t字符串进行搜索r 表示的模式匹配的内容,并全部替换为s所表示的内容
    echo "2008:08:08 08:08:08" | awk ‘gsub(/:/,“-",$0)'
split(s,array,[r]) :以r 为分隔符,切割字符串s,并将切割后的结果保存至array所表示的数组中,第一个索引值为1,第二个索引值为2,…
    netstat -tan | awk '/^tcp\>/{split($5,ip,":");count[ip[1]]++} END{for (i in count) {print i,count[i]}}'

内建字符串函数

函数 描述
gsub(r,s) 将$0中所有出现的r替换为 s,返回替换发生的次数.
gsub(r,s,t ) 将字符串t中所有出现的r替换为s,返回替换发生的次数
index(s,t) 返回字符串t在s中第一次出现的位置, 如果t没有出现的话, 返回 0.
length(s) 返回 s 包含的字符个数
match(s,r) 测试 s 是否包含能被 r 匹配的子串, 返回子串的起始位置或0; 设置RSTART与RLENGTH
split(s,a) 用FS将 s 分割到数组 a 中, 返回字段的个数
split(s,a,fs) 用fs分割 s 到数组 a 中, 返回字段的个数
sprintf(fmt,expr-list) 根据格式字符串 fmt 返回格式化后的expr-list
sub(r,s) 将 $0 的最左最长的, 能被 r 匹配的子字符串替换为s,返回替换发生的次数.
sub(r,s,t) 把 t 的最左最长的, 能被 r 匹配的子字符串替换为 s,返回替换发生的次数.
substr(s,p) 返回 s 中从位置 p 开始的后缀.
substr(s,p,n) 返回 s 中从位置 p 开始的, 长度为 n 的子字符串.
  • 自定义函数
格式:
    function name ( parameter, parameter, ... ) {
        statements
        return expression
    }
示例:
    cat fun.awk
        function max(v1,v2) {
            v1>v2?var=v1:var=v2
            return var
        }
        BEGIN{a=3;b=2;print max(a,b)}
    awk –f fun.awk

awk中调用shell命令

  • system命令
  • 空格是awk中的字符串连接符,如果system中需要使用awk中的变量可以使用空格分隔,或者说除了awk的变量外其他一律用""引用起来。
awk BEGIN'{system("hostname") }'
awk 'BEGIN{score=100; system("echo your score is " score) }'

awk脚本

  • 将awk 程序写成脚本,直接调用或执行
  • 示例:
cat f1.awk
    {if($3>=1000)print $1,$3}

awk -F: -f f1.awk /etc/passwd

cat f2.awk
    #!/bin/awk –f
    #this is a awk script
    {if($3>=1000)print $1,$3}
chmod +x f2.awk
f2.awk –F: /etc/passwd

向awk脚本传递参数

格式:
    awkfile var=value var2=value2... Inputfile
注意:在BEGIN 过程 中不可用。直到首行输入完成以后 ,变量才可用 。可以通过-v参数,让awk 在执行BEGIN之前得到变量的值。命令行中每一个指定的变量都需要一个-v参数

示例:
    cat test.awk
        #!/bin/awk –f
        {if($3 >=min && $3<=max)print $1,$3}
    chmod +x test.awk
    
    test.awk -F: min=100 max=200 /etc/passwd
  • 练习
1、统计/etc/fstab 文件中每个文件系统类型出现的次数
2、统计/etc/fstab 文件中每个单词出现的次数
3、提取出字符串Yd$C@M05MB%9&Bdh7dq+YVixp3vpw中的所有数字
4、解决DOS攻击生产案例:根据web 日志或者或者网络连接数,监控当某个IP并发连接数或者短时内PV 达到100,即调用防火墙命令封掉对应的IP ,监控频率每隔5 分钟。防火墙命令为:iptables -A INPUT -s IP -j REJECT
最后编辑于
©著作权归作者所有,转载或内容合作请联系作者
  • 序言:七十年代末,一起剥皮案震惊了整个滨河市,随后出现的几起案子,更是在滨河造成了极大的恐慌,老刑警刘岩,带你破解...
    沈念sama阅读 151,511评论 1 330
  • 序言:滨河连续发生了三起死亡事件,死亡现场离奇诡异,居然都是意外死亡,警方通过查阅死者的电脑和手机,发现死者居然都...
    沈念sama阅读 64,495评论 1 273
  • 文/潘晓璐 我一进店门,熙熙楼的掌柜王于贵愁眉苦脸地迎上来,“玉大人,你说我怎么就摊上这事。” “怎么了?”我有些...
    开封第一讲书人阅读 101,595评论 0 225
  • 文/不坏的土叔 我叫张陵,是天一观的道长。 经常有香客问我,道长,这世上最难降的妖魔是什么? 我笑而不...
    开封第一讲书人阅读 42,558评论 0 190
  • 正文 为了忘掉前任,我火速办了婚礼,结果婚礼上,老公的妹妹穿的比我还像新娘。我一直安慰自己,他们只是感情好,可当我...
    茶点故事阅读 50,715评论 3 270
  • 文/花漫 我一把揭开白布。 她就那样静静地躺着,像睡着了一般。 火红的嫁衣衬着肌肤如雪。 梳的纹丝不乱的头发上,一...
    开封第一讲书人阅读 39,672评论 1 192
  • 那天,我揣着相机与录音,去河边找鬼。 笑死,一个胖子当着我的面吹牛,可吹牛的内容都是我干的。 我是一名探鬼主播,决...
    沈念sama阅读 31,112评论 2 291
  • 文/苍兰香墨 我猛地睁开眼,长吁一口气:“原来是场噩梦啊……” “哼!你这毒妇竟也来了?” 一声冷哼从身侧响起,我...
    开封第一讲书人阅读 29,837评论 0 181
  • 序言:老挝万荣一对情侣失踪,失踪者是张志新(化名)和其女友刘颖,没想到半个月后,有当地人在树林里发现了一具尸体,经...
    沈念sama阅读 33,417评论 0 228
  • 正文 独居荒郊野岭守林人离奇死亡,尸身上长有42处带血的脓包…… 初始之章·张勋 以下内容为张勋视角 年9月15日...
    茶点故事阅读 29,928评论 2 232
  • 正文 我和宋清朗相恋三年,在试婚纱的时候发现自己被绿了。 大学时的朋友给我发了我未婚夫和他白月光在一起吃饭的照片。...
    茶点故事阅读 31,316评论 1 242
  • 序言:一个原本活蹦乱跳的男人离奇死亡,死状恐怖,灵堂内的尸体忽然破棺而出,到底是诈尸还是另有隐情,我是刑警宁泽,带...
    沈念sama阅读 27,773评论 2 234
  • 正文 年R本政府宣布,位于F岛的核电站,受9级特大地震影响,放射性物质发生泄漏。R本人自食恶果不足惜,却给世界环境...
    茶点故事阅读 32,253评论 3 220
  • 文/蒙蒙 一、第九天 我趴在偏房一处隐蔽的房顶上张望。 院中可真热闹,春花似锦、人声如沸。这庄子的主人今日做“春日...
    开封第一讲书人阅读 25,827评论 0 8
  • 文/苍兰香墨 我抬头看了看天上的太阳。三九已至,却和暖如春,着一层夹袄步出监牢的瞬间,已是汗流浃背。 一阵脚步声响...
    开封第一讲书人阅读 26,440评论 0 180
  • 我被黑心中介骗来泰国打工, 没想到刚下飞机就差点儿被人妖公主榨干…… 1. 我叫王不留,地道东北人。 一个月前我还...
    沈念sama阅读 34,523评论 2 249
  • 正文 我出身青楼,却偏偏与公主长得像,于是被迫代替她去往敌国和亲。 传闻我的和亲对象是个残疾皇子,可洞房花烛夜当晚...
    茶点故事阅读 34,583评论 2 249

推荐阅读更多精彩内容

  • awk:报告生成器,格式化文本输出 内容: awk介绍 awk基本用法 awk变量 awk格式化 awk操作符 a...
    BossHuang阅读 1,424评论 0 9
  • awk介绍awk变量printf命令:实现格式化输出操作符awk patternawk actionawk数组aw...
    哈喽别样阅读 1,480评论 0 4
  • 本章主要学习内容awk介绍 awk基本用法 awk变量 awk格式化 awk操作符 awk条件判断 a...
    楠人帮阅读 1,211评论 0 8
  • awk: grep,sed,awk grep:文本过滤 sed:文本编辑 awk:文本格式化工具; 1 什么是aw...
    木林森阅读 1,687评论 0 16
  • 转载 原文的排版和内容都更加友好,并且详细,我只是在这里贴出了一部分留作自己以后参考和学习,如希望更详细了解AWK...
    XKirk阅读 3,147评论 2 25