[因为最近项目比较忙，所以会先翻译一下文档，有空再写android进阶相关文章，大家耐心等待哈]
非运算
非运算是用!表示的，是对boolean表达式做反运算，特别是，非运算可以跟一些groovy中真的情况进行使用:
assert (!true) == false 1
assert (!'foo') == false 2
assert (!'') == true 3
1.true的非运算结果是false
2.'foo'是非空的字符串，被解析成true，所以非运算后返回false
3.'' 是空字符串，被解析成false，所以非运算后返回true
三元运算符
三元运算符是if／else赋值一些值给一个变量的缩写表达式：
用来替代下面这个的：
if (string!=null && string.length()>0) {
result = 'Found'
} else {
result = 'Not found'
}
你可以写成这样：
result = (string!=null && string.length()>0) ? 'Found' : 'Not found'
三元运算符也支持groovy中真的情况，你也可以简写成：
result = string ? 'Found' : 'Not found'
Elvis运算符
Elvis运算符是三元运算符的简写形式。一个例子就是当一个表达式返回false的时候要返回一个默认值这是最很方便的。（跟groovy中真的情况类似）一个简单的例子如下：
displayName = user.name ? user.name : 'Anonymous' 1
displayName = user.name ?: 'Anonymous' 2
1.使用三元运算符，你必须重复写你要赋值的这个值
2.使用Elvis运算符，这个值就会被检测，如果不是false的话那么就被赋值
使用Elvis运算符可以避免你的代码冗长，减少重构的错误，通过移除一些条件判断和确定的返回值来精简表达式。
对象运算符
安全占位符
安全占位符(?.)是用于避免空指针异常NullPointerException,特别是对象的引用要访问它的方法或者属性时候。为防止对象引用为空出现null异常，安全占位符会在对象引用为null的时候直接返回null，而不是报一个null异常。就像下面这样：
def person = Person.find { it.id == 123 } 1
def name = person?.name 2
assert name == null 3
1.find会返回null实例
2.使用安全占位符来避免出现空指针异常
3.结果是null
直接属性访问操作符
通常在Groovy中，当你像这样写代码：
class User {
public final String name 1
User(String name) { this.name = name}
String getName() { "Name: $name" } 2
}
def user = new User('Bob')
assert user.name == 'Name: Bob' 3
1.public的属性name
2.name的getter方法，返回一个自定义的字符串
3.调用getter方法
user.name会触发调用name属性的getter方法来得到name，如果你想要代替通过getter来获得属性，你可以使用直接属性访问操作符。
assert user.@name == 'Bob' 1
1.操作符.@会代替通过getter方法来获取属性
方法指针操作符
方法指针操作符.&用于保存方法的引用在一个变量上面，过后可以调用：
def str = 'example of method reference' 1
def fun = str.&toUpperCase 2
def upper = fun() 3
assert upper == str.toUpperCase() 4
-
str变量包含了一个字符串
2.保存str上面的toUpperCase方法到一个变量fun中
3.fun方法可以像普通方法一样被调用
4.验证结果和直接调用str上面的这个方法是否一致
使用方法指针有很多好处，首先这个类型指针是闭包groovy.lang.Closure,所以它可以像闭包那么使用。特别是，使用现有的方法来实现策略模式。
def transform(List elements, Closure action) { 1
def result = []
elements.each {
result << action(it)
}
result
}
String describe(Person p) { 2
"$p.name is $p.age"
}
def action = this.&describe 3
def list = [
new Person(name: 'Bob', age: 42),
new Person(name: 'Julia', age: 35)] 4
assert transform(list, action) == ['Bob is 42', 'Julia is 35'] 5
-
transform方法会遍历elements集合，然后每个元素作为action方法的参数，处理完拼接成一个新的集合返回。
2.我们定义一个接收Person类型的参数，然后返回一个string字符串
3.我们创建一个方法指针在descibe方法上面
4.我们创建一个集合，然后要获取它的描述
5.方法指针可以用在使用闭包Closure的地方。
方法指针可以通过接收者和方法名进行绑定，参数只有在运行时才会被关联，意思就是说如果你有多个相同名字的方法，语法上是相同的，只有在运行的时候，正确的方法才会被调用：
def doSomething(String str) { str.toUpperCase() } 1
def doSomething(Integer x) { 2*x } 2
def reference = this.&doSomething 3
assert reference('foo') == 'FOO' 4
assert reference(123) == 246 5
1.定义一个重载的doSomething方法，接收一个String类型参数
2.定义一个重载的doSomething方法，接受一个int类型参数
3.创建一个方法指针在doSomething方法上，但是没有明确指明它的参数
4.使用方法指针传一个String类型的参数，它就会调用带String参数的doSomething方法
5.使用方法指针传一个int类型的参数，它就会调用带int参数的doSomething方法
正则表达式操作符
模式操作符~提供了创建java.util.regex.Pattern实例的简单方法：
def p = ~/foo/
assert p instanceof Pattern
通常，你会在带/的字符串中看到正则表达式操作符，它能使用在任何类型的String上。
p = ~'foo' 1
p = ~"foo" 2
p = ~$/dollar/slashy $ string/$ 3
p = ~"${pattern}" 4
1.使用单引号字符串
2.使用双引号字符串
3.$/字符串让你使用/和$符而不需要进行编码
4.你也可以使用String
查找操作符
另外创建模式，你可以直接使用查找操作符=~来创建java.util.regex.Matcher实例：
def text = "some text to match"
def m = text =~ /match/ 1
assert m instanceof Matcher 2
if (!m) { 3
throw new RuntimeException("Oops, text not found!")
}
1.=~操作符创建一个mather来匹配text变量，将=~放在右边
2.=~返回的类型是Matcher
3.相当于调用if (!m.find())
Matcher会通过调用find方法强制返回boolean类型，当=~作为判断出现的时候（像在if和while中一样）和perl中的=~运算符的作用是一样的。
匹配运算符
匹配运算符==~是查找运算符的小小变形，它不是返回一个Matcher，而是返回一个严格匹配后的bool值。
m = text ==~ /match/ 1
assert m instanceof Boolean 2
if (m) { 3
throw new RuntimeException("Should not reach that point!")
}
1.==~使用正则表达式来做匹配，而且匹配是严格的
2.==~返回的类型是一个bool值
3.相当于调用if (text ==~ /match/)
